Bøvl med mutex

Hvad med at du lige før du kalder messageBox opretter endnu en mutex som du så fjerner igen efter messagebox. Du starter så med at checke om denne mutex findes og gør den det ved du at program nr. 2 er startet og viser en messagebox.

Ja, men hvordan giver jeg så den messageBox, som allerede eksisterer fokus?

Det ved jeg ikke.

Hej hr. Hallandsen

Hvad med dette?

Hilsen hr. Hallandsen

--------------------------------------------------------------------------------------

unit CheckPrevious;

interface

uses Windows, SysUtils, Forms;

function RestoreIfRunning: Boolean;

implementation

type
  PInstanceInfo = ^TInstanceInfo;
  TInstanceInfo = packed record
    FirstHandle: THandle;
    PreviousHandle: THandle;
    RunCounter: Integer;
  end;

var
  InstanceInfo: PInstanceInfo;
  MappingHandle: THandle;
  MappingName: string;
  RemoveMe: Boolean = True;


function RestoreIfRunning: Boolean;
begin
  Result := True;
  MappingName := StringReplace(ParamStr(0), '\', '', [rfReplaceAll, rfIgnoreCase]);
  MappingHandle := CreateFileMapping($FFFFFFFF, nil, PAGE_READWRITE, 0, SizeOf(TInstanceInfo), PChar(MappingName));
  if MappingHandle = 0 then
    RaiseLastOSError
  else
  begin
    InstanceInfo := MapViewOfFile(MappingHandle, FILE_MAP_ALL_ACCESS, 0, 0, SizeOf(TInstanceInfo));
    if (GetLastError <> ERROR_ALREADY_EXISTS) or (not IsWindow(InstanceInfo^.FirstHandle)) then
    begin
      InstanceInfo^.FirstHandle := Application.Handle;
      if GetLastError <> ERROR_ALREADY_EXISTS then
      begin
        InstanceInfo^.PreviousHandle := Application.Handle;
        InstanceInfo^.RunCounter := 1;
      end
      else
        InstanceInfo^.RunCounter := 1 + InstanceInfo^.RunCounter;
      Result := False;
    end
    else //Already runing
    begin
      MappingHandle := OpenFileMapping(FILE_MAP_ALL_ACCESS, False, PChar(MappingName));
      if MappingHandle <> 0 then
      begin
        InstanceInfo := MapViewOfFile(MappingHandle, FILE_MAP_ALL_ACCESS, 0, 0, SizeOf(TInstanceInfo));
        if InstanceInfo^.RunCounter > 1 then
        begin
          if IsIconic(InstanceInfo^.PreviousHandle) then
            ShowWindow(InstanceInfo^.PreviousHandle, SW_RESTORE);
          SetForegroundWindow(InstanceInfo^.PreviousHandle);
          RemoveMe := False;
          Halt;
        end
        else
        begin
          InstanceInfo^.PreviousHandle := Application.Handle;
          InstanceInfo^.RunCounter := 1 + InstanceInfo^.RunCounter;
        end;
      end;
    end;
  end;
end;

initialization

finalization

if RemoveMe then //Remove one instance
begin
  MappingHandle := OpenFileMapping(FILE_MAP_ALL_ACCESS, False, PChar(MappingName));
  if MappingHandle <> 0 then
  begin
    InstanceInfo := MapViewOfFile(MappingHandle, FILE_MAP_ALL_ACCESS, 0, 0, SizeOf(TInstanceInfo));
    InstanceInfo^.RunCounter := -1 + InstanceInfo^.RunCounter;
  end
  else
    RaiseLastOSError;
end;

if Assigned(InstanceInfo) then
  UnmapViewOfFile(InstanceInfo);
if MappingHandle <> 0 then
  CloseHandle(MappingHandle);

end.