Valg af ark til print

Jeg skulle ikke mene, at dette er muligt.

Jeg har selv været igang med at finde en sådan funktion under udskriftsdelen.

En anden løsning kunne være at skjule de uønskede ark. Jeg vil mene at dette ville kunne løse dit problem.


Jeg skal dog ikke kunne sige om noget programering ville kunne løse dit problem, men jeg kender ikke til nogen løsning via programering.



Mvh.
Anders

Jeg har denne kode som starter en liste hvor du kan vælge hvilket ark du vil printe ud, men den vælger alle ark (ikke de skjulte) så en løsning kunne selvfølgelig være at skjule de øvrige ark. Men det kunne jo være der fandtes en anden løsning - jeg gir det lige en chance.

Her er kode som viser alle ark:

Option Explicit

Sub Printtotal()
    Dim i As Integer
    Dim TopPos As Integer
    Dim SheetCount As Integer
    Dim PrintDlg As DialogSheet
    Dim CurrentSheet As Worksheet
    Dim OriginalSheet As Worksheet
    Dim cb As CheckBox
    Application.ScreenUpdating = False

'  Check for protected workbook
    If ActiveWorkbook.ProtectStructure Then
        MsgBox "Projektmappen er beskyttet!", vbCritical
        Exit Sub
    End If

'  Add a temporary dialog sheet
    Set OriginalSheet = ActiveSheet
    Set PrintDlg = ActiveWorkbook.DialogSheets.Add

    SheetCount = 0

'  Add the checkboxes
    TopPos = 40
    For i = 1 To ActiveWorkbook.Worksheets.Count
        Set CurrentSheet = ActiveWorkbook.Worksheets(i)
'      Skip empty sheets and hidden sheets
        If Application.CountA(CurrentSheet.Cells) <> 0 And _
            CurrentSheet.Visible Then
            SheetCount = SheetCount + 1
            PrintDlg.CheckBoxes.Add 78, TopPos, 150, 16.5
                PrintDlg.CheckBoxes(SheetCount).Text = _
                    CurrentSheet.Name
            TopPos = TopPos + 13
        End If
    Next i

'  Move the OK and Cancel buttons
    PrintDlg.Buttons.Left = 240

'  Set dialog height, width, and caption
    With PrintDlg.DialogFrame
        .Height = Application.Max _
            (68, PrintDlg.DialogFrame.Top + TopPos - 34)
        .Width = 230
        .Caption = "Vælg hvilke ark der skal udskrives"
    End With

'  Change tab order of OK and Cancel buttons
'  so the 1st option button will have the focus
    PrintDlg.Buttons("Button 2").BringToFront
    PrintDlg.Buttons("Button 3").BringToFront

'  Display the dialog box
    OriginalSheet.Activate
    Application.ScreenUpdating = True
    If SheetCount <> 0 Then
        If PrintDlg.Show Then
            For Each cb In PrintDlg.CheckBoxes
                If cb.Value = xlOn Then
                    Worksheets(cb.Caption).Select Replace:=False
                End If
            Next cb
            ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True
'          ActiveSheet.Select
        End If

    Else
        MsgBox "Alle ark er tomme!"
    End If

'  Delete temporary dialog sheet (without a warning)
    Application.DisplayAlerts = False
    PrintDlg.Delete

'  Reactivate original sheet
    OriginalSheet.Activate
End Sub


//kvisten 63

Sub udskriv()

Application.ScreenUpdating = False

    Sheets("Ark1").PrintOut Copies:=1, Collate:=True
    Sheets("Ark2").PrintOut Copies:=1, Collate:=True
    Sheets("Ark3").PrintOut Copies:=1, Collate:=True
    Sheets("Ark4").PrintOut Copies:=1, Collate:=True
    Sheets("Ark5").PrintOut Copies:=1, Collate:=True

Application.ScreenUpdating = True

End Sub

noget i denne stil?

Jeg klarer det med den med min egen løsning - ved at skjule de øvrige ark.

//kvisten63

kvisten63! det var ellers chuckieth9 der kom med den løsning, så det var faktisk ham som skulle have de udlovede point.