Paging mysql

kig på LIMIT i en SELECT

fx SELECT * FROM tabel LIMIT 0,3
0 = fra række 0
3 = til række 3

Dvs hvis du skriver 0,10
så viser den de første 10 poster i din tabel

Jammen det lyder fint man hvordan sættes det op for jeg går da ud fra at man skrive noget med <% et eller andet %> *GG* jeg er sku helt på bar bund hvad det angår

Så synes jeg egentlig du skulle starte med noget nemmere.

Øhm.. hvis du ska lave det fra dosprompt

så skal du lige ind og vælge databasen og alt det der...

også skriver man bare
SELECT * FROM tabel_navn LIMIT 0,3

Det du kommer med lyder som noget asp.. og det kender jeg ikke... men jeg kender PHP hvor man fx laver det sådan her
$query = mysql_query(\"
SELECT *
FROM tabelnavn
LIMIT 0,3\") OR DIE (mysql_error());

se om dette virker?

<%
'Opretter Connection
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "DRIVER={MySQL}; server=localhost; database=test; uid=; pwd=;"


'Først skal vi have antallet af poster
Set objRs = Conn.Execute("SELECT COUNT(*) AS records FROM tabel;")
intRecords = int(objRs("records"))
objRs.Close
Set objRs = Nothing

'Variabler til query'et
intPage = Request.QueryString("page")
if intPage = "" OR not isNumeric(intPage) then
    intPage = int(1)
else
    intPage = int(intPage)
end if

intPageSize = int(5)
intStart = intPage*intPageSize
intStart = intStart-intPageSize
intPages = int(intRecords/intPageSize)+1

intValue = (intRecords - intStart)
If intPageSize > intValue Then
    intPageSize = intValue
end if

Set objRs = Conn.Execute("SELECT * FROM tabel LIMIT " & intStart & ", " & intPageSize & ";")
   
    if objRs.EOF or objRs.BOF then
        Response.Write "Ingen poster"
    else
        Response.Write "<table border=""1"" cellpadding=""3"">"
            Response.Write "<tr>"
                Response.Write "<td><b>id</b></td>"
                Response.Write "<td><b>Site</b></td>"
            Response.Write "</tr>"
               
            Do until objRs.EOF
                Response.Write "<tr>"
                    Response.Write "<td>" & objRs("id") & "</td>"
                    Response.Write "<td><a href=""" & objRs("url") & """>" & objRs("navn") & "</a></td>"
                Response.Write "</tr>"
            objRs.MoveNext
            Loop
        Response.Write "</table>"
    end if

objRs.Close
Set objRs = Nothing

'Udskriver en "sideliste"
For i = 1 to intPages
    if i = intPage then
        Response.Write "<b>" & i & "</b> "
    else
        Response.Write "<a href=""paging.asp?page=" & i & """>"
        Response.Write i
        Response.Write "</a> "
    end if
next

Conn.Close
Set Conn = Nothing
%>