Slette fra en XML fil

Det mest simple, som jeg ofte bruger, er vel at benytte pos og posex funktionerne til at finde "<Logfiles>" (i1) og "</Logfiles>" (i2) og så slette alt mellem i1 og i2

Jeg var inde på noget med at loade filen ind i en TStringlist og så søge i den og slette mellem de 2 forekomster.
Men jeg ser et mindre problem i at XML dokumentet jo er loadet i memory så jeg skal lige have checket om det virker med først at gemme det og så lave det Stringlist nummer og så loade det igen efterfølgende.

Det undrer mig bar at der ikke er standard funktioner til det.

Jeg kan ikke se noget problem...

I hvad ?

:-) Du skriver "Men jeg ser et mindre problem i at XML dokumentet...", jeg er ikke helt klar over hvad problemet skulle være.

Hvis jeg nu begynder at manipulere med filen mens den stadig er loadet i memory så vil de ændringer jeg har lavet jo bare blive overskrevet når filen skrives fra memory - som jeg ser det

Mener du at der er andre programmer som også ændre i filen?

Nej
Men så vidt jeg kan hitte frem til så bliver XML loadet i memory og kun skrevet når dokumentet releases.
Men jeg kan have misforstået noget

Hvilket program laver din XML fil og når du skal til at ændre i det har dette program så stadig loadet XML filen?

Det er mit eget program der styrer det hele.
Det er et led i et større projekt hvor jeg er ved at lave nogle generelle moduler til at styre gemme/læse opsætning af program enten i DB, INI, Registry eller XML

Min klasse til XML er nedenfor hvis det giver mening

//*********************************************************
// Class for connecting to XML file
// Used for storing settings
// © OZ8HP Hugo Pedersen
//*********************************************************
unit U_Storage.Xml;

{$I Defines.inc}

interface

uses
  Forms, SysUtils, Windows, XmlIntf, XMLDoc;

type
  TSettingsConn = class
  private
    fModified: boolean;
    fConfigfile: string;
    fXMLDoc: TXMLDocument;
  public
    constructor Create(const FileName: string); overload;
    constructor Create; overload;
    property ConfigFile: string read fConfigFile write fConfigFile;

    procedure SaveFile;

    function ReadString(aSection, aKey, aDefault: string): string;
    procedure WriteString(aSection, aKey, aValue: string);

    function Readboolean(const aSection, aKey: string; aDefault: boolean): boolean;
    procedure Writeboolean(const aSection, aKey: string; aValue: boolean);
    function ReadDate(const aSection, aKey: string; const aDefault: TDate): TDate;
    procedure WriteDate(const aSection, aKey: string; const aValue: TDate);
    function ReadInteger(const aSection, aKey: string; aDefault: integer): integer;
    procedure WriteInteger(const aSection, aKey: string; aValue: integer);

    procedure AppendSection(const aSection: string);
    procedure ClearSection(const aSection : string);
    procedure InsertSection(const Old, New : string);
    procedure UpdateFile;
  end;

var
  SettingsConn: TSettingsConn;

implementation

uses
  Vcl.Dialogs,
  U_AppConsts;


// Start of functions and procedures for helping class
function CleanaValue(aValue: string): string;
begin
  aValue := StringReplace(aValue, ' ',  '_',  [rfReplaceAll, rfIgnoreCase]);
  Result := aValue;
end;

function SettingsFileBuild: string;
begin
  Result := ChangeFileExt(Application.ExeName, '.xml');
{$IFDEF USESETTINGS}
  Result := ExtractFilePath(Application.ExeName) + 'settings.xml';
{$ENDIF}
end;
// End of functions and procedures for helping class

{ TSettingsConn }
constructor TSettingsConn.Create(const FileName: string);
begin
  inherited Create;
  fConfigfile    := FileName;
  fXMLDoc        := TXMLDocument.Create(Application);
  fXMLDoc.Options := [doNodeAutoIndent];
  if FileExists(fConfigfile) then
    fXMLDoc.LoadFromFile(fConfigfile)
  else
    begin
      fXMLDoc.Active := True;
      fXMLDoc.AddChild('Configuration');
      fXMLDoc.SaveToFile(fConfigfile);
    end;
end;

constructor TSettingsConn.Create;
begin
  Create(SettingsFileBuild);
end;

procedure TSettingsConn.SaveFile;
begin
  if not fModified then
    Exit;
  fXMLDoc.Active := True;
  fXMLDoc.SaveToFile(fConfigfile);
  fModified := False;
end;

// *****************************************************************************
//  Everything in XML is read/write as strings
// *****************************************************************************
function TSettingsConn.ReadString(aSection, aKey, aDefault: string): string;
var
  Node: IXMLNode;
  Child: IXMLNode;
begin
  aSection := CleanaValue(aSection);
  aKey := CleanaValue(aKey);
  Node := fXMLDoc.DocumentElement.ChildNodes.FindNode(aSection);

  if not Assigned(Node) then
    begin
      Result := aDefault;
      Exit;
    end;

  Child:= Node.ChildNodes.FindNode(aKey);
  if not Assigned(Child) then
    begin
      Result := aDefault;
      Exit;
    end;

  Result := Child.Text;
end;

procedure TSettingsConn.WriteString(aSection, aKey, aValue: string);
var
  Node: IXMLNode;
  Child: IXMLNode;
begin
  aSection := CleanaValue(aSection);
  aKey := CleanaValue(aKey);
  if ReadString(aSection, aKey, '') = aValue then
    Exit;

  Node := fXMLDoc.DocumentElement.ChildNodes.FindNode(aSection);
  if not Assigned(Node) then
    Node := fXMLDoc.DocumentElement.AddChild(aSection);

  Child:= Node.ChildNodes.FindNode(aKey);
  if not Assigned(Child) then
    Child:= Node.AddChild(aKey);

  Child.Text := aValue;
  fModified := True;
  SaveFile;
end;

// *****************************************************************************
//  All other datatypes are converted and read/write as string
// *****************************************************************************
function TSettingsConn.Readboolean(const aSection, aKey: string; aDefault: boolean): boolean;
begin
  Result := boolean(ReadInteger(aSection, aKey, integer(aDefault)));
end;

function TSettingsConn.ReadDate(const aSection, aKey: string; const aDefault: TDate): TDate;
begin
  Result := StrToDate(ReadString(aSection, aKey, DateToStr(aDefault)));
end;

function TSettingsConn.ReadInteger(const aSection, aKey: string; aDefault: integer): integer;
begin
  Result := StrToInt(ReadString(aSection, aKey, IntToStr(aDefault)));
end;

procedure TSettingsConn.Writeboolean(const aSection, aKey: string; aValue: boolean);
begin
  WriteInteger(aSection, aKey, Integer(aValue));
end;

procedure TSettingsConn.WriteDate(const aSection, aKey: string; const aValue: TDate);
begin
  WriteString(aSection, aKey, DateToStr(aValue));
end;

procedure TSettingsConn.WriteInteger(const aSection, aKey: string; aValue: integer);
begin
  WriteString(aSection, aKey, IntToStr(aValue));
end;
// *****************************************************************************


// *****************************************************************************
//  Following procedures are here to make all connections look the same
//  They are standard in FastIniFile
// *****************************************************************************
procedure TSettingsConn.AppendSection(const aSection: string);
begin
  // Dummy procedure to make class look like other connection classes
end;

procedure TSettingsConn.ClearSection(const aSection : string);
begin
  // Dummy procedure
end;

procedure TSettingsConn.InsertSection(const Old, New : string);
begin
  // Dummy procedure
end;

procedure TSettingsConn.UpdateFile;
begin
  // Dummy procedure
end;

// Getters and setters

initialization
  SettingsConn := TSettingsConn.Create;

finalization
  FreeAndNil(SettingsConn);


end.

procedure TSettingsConn.ClearSection(const aSection : string);
var
  Node: IXMLNode;
begin
  Node := fXMLDoc.DocumentElement.ChildNodes.FindNode(aSection);
  if Assigned(Node) then
        fXMLDoc.DocumentElement.ChildNodes.Remove(Node);

  fModified := True;
  SaveFile;
end;

Det var da ikke så slemt som jeg havde regnet med :-)

Der er nogle meget kryptiske løsninger der ude som har forvirret mig hele dagen.

Men smid et svar kroning.

Svar

Og den skal nok rettes til:

procedure TSettingsConn.ClearSection(const aSection : string);
var
  Node: IXMLNode;
begin
  Node := fXMLDoc.DocumentElement.ChildNodes.FindNode(aSection);
  if Assigned(Node) then
  begin
        fXMLDoc.DocumentElement.ChildNodes.Remove(Node);

      fModified := True;
      SaveFile;
  end;
end;

Ingen grund til at SaveFile hvis der ikke er slettet noget.

Nej og det vil vel også være en sikkerhed mod fejl hvis man forsøger at slette en node der ikke findes.