Slet øverste linie i tekst

Prøv med

=IF(ISNUMBER(FIND("ABC"&CHAR(10);A2));RIGHT(A2;LEN(A2)-FIND(CHAR(10);A2));A2)

På dansk

=HVIS(ER.TAL(FIND("ABC"&TEGN(10);A2));HØJRE(A2;LÆNGDE(A2)-FIND(TEGN(10);A2));A2)

Virker. Fantastisk. En enkelt ting:
Den returnerer "Yderligere tekst 1Yderligere tekst 2" i én linje. Kan den beholde det i to linjer som i den oprindelige tekst?

En anden ting:
Hvis cellen indeholder
31.11.2017 18:30 ABC
Yderligere tekst 1
Yderligere tekst 2
10.09.2017 14:45 ABC
Yderligere tekst 1
Yderligere tekst 2
03.04.2017 16:42 ABC
Yderligere tekst 1
Yderligere tekst 2

Kan den så slette alt fra anden gang der står dd.mm.åååå tt:mm, så følgende returneres:
31.11.2017 18:30 ABC
Yderligere tekst 1
Yderligere tekst 2
(alt under er fjernet)

Dit første problem er blot et spørgsmål om formateringen af cellen. Sæt den til at acceptere ombrydning af teksten. Det andet problem skal jeg lige tænke over

Hvis du sætter en funktion ind i et modul (Alt F11 + indsæt modul) med denne kode:

Function FindN(sFindWhat As String, _
sInputString As String, N As Integer) As Integer
Dim J As Integer
Application.Volatile
FindN = 0
For J = 1 To N
FindN = InStr(FindN + 1, sInputString, sFindWhat)
If FindN = 0 Then Exit For
Next
End Function

kan det lade sig gøre med denne formel:

=LEFT(A2;findn(CHAR(10);A2;3))

På dansk:

=VENSTRE(A2;findn(TEGN(10);A2;3))

Tak for din løsning det virker fint når teksten står i celle A2.
Hvis jeg kopierer teksten til celle A1 og indsætter
=VENSTRE(A1;findn(TEGN(10);A1;3))
returnere den blot en tom celle.
Gør jeg noget forkert?

Glem mit spørgsmål ovenfor. Jeg har fået løst det.
Efter at have indsat funktionen, kan jeg ikke få
=HVIS(ER.TAL(FIND("ABC"&TEGN(10);A2));HØJRE(A2;LÆNGDE(A2)-FIND(TEGN(10);A2));A2)
til at virke.
Gør jeg noget forkert?

Hvad svar giver den? Husk at der er to forskellige løsninger: Det der løser det oprindelige problem, og det der løser det problem du formulerer i #2. Hvilket af dem ønsker du at få løsning på?

Løsning #2 virker fint. Løsning #1 (fjernelse af linjen med formatet dd.mm.åååå mm:tt ABC) kan jeg ikke få til at virke sammen med løsning #2. Der kommer ingen fejlmeddelelse, linjen med ovenstående format fjernes ikke.
Jeg har behov for een løsning der løser #1 og #2.
På forhånd tak!

Hvis du kombinerer de to formler bliver det til:

=HVIS(ER.TAL(FIND("ABC"&TEGN(10);VENSTRE(A2;findn(TEGN(10);A2;3))));HØJRE(VENSTRE(A2;findn(TEGN(10);A2;3));LÆNGDE(VENSTRE(A2;findn(TEGN(10);A2;3)))-FIND(TEGN(10);VENSTRE(A2;findn(TEGN(10);A2;3))));VENSTRE(A2;findn(TEGN(10);A2;3)))

Glem mit seneste svar. Det virker kun, hvis der er mere end 3 linier i cellen. Prøv i stedet med 2 kolonner. I B2 skrives:

=HVIS(findn(TEGN(10);A2;3)>0;VENSTRE(A2;findn(TEGN(10);A2;3));A2)

Og i C2 skrives:

=HVIS(ER.TAL(FIND("ABC"&TEGN(10);B2));HØJRE(B2;LÆNGDE(B2)-FIND(TEGN(10);B2));B2)

Og kopier nedefter

Hvis du ønsker at kombinere det til en formel, bliver den lidt stor:

=HVIS(ER.TAL(FIND("ABC"&TEGN(10);HVIS(findn(TEGN(10);A2;3)>0;VENSTRE(A2;findn(TEGN(10);A2;3));A2)));HØJRE(HVIS(findn(TEGN(10);A2;3)>0;VENSTRE(A2;findn(TEGN(10);A2;3));A2);LÆNGDE(HVIS(findn(TEGN(10);A2;3)>0;VENSTRE(A2;findn(TEGN(10);A2;3));A2))-FIND(TEGN(10);HVIS(findn(TEGN(10);A2;3)>0;VENSTRE(A2;findn(TEGN(10);A2;3));A2)));HVIS(findn(TEGN(10);A2;3)>0;VENSTRE(A2;findn(TEGN(10);A2;3));A2))

Det virker nu. Tusind tak for hjælpen Jens48.
Du har været en stor hjælp!!!