Sum i forskellige kolonner

Hvad er P1 - P12?

Det er periode 1 til periode 12 (jan-Dec i et givent år).

Jeg fandt en læsning ved at lave en variabel i sum og så tage alle perioder i året hver gang selvom jeg egentlig kun er i februar, men så vil den bare vise tomme kolonner, hvilket er helt fint.

Du kan gøre det i en dynamisk pivotering. Jeg viser det lige i morgen, så har jeg min computer hjemme :) Uden tomme kolonner :)

Som lovet:

drop table dbo.testperiods

Create  table dbo.testPeriods (Period nvarchar(50),account int, amount int)

insert into dbo.testPeriods
values

('2018M1',      25    ,        10 ),
('2018M1',      40    ,        20 ),
('2018M2',      30    ,        30 ),
('2018M2',      35    ,        20 ),
('2018M2',      90    ,        50 ),
('2018M2',      90    ,        50 ),
('2018M1',      90    ,        50 ),
('2018M3',      90    ,        50 )




DECLARE @Str NVARCHAR(MAX);
DECLARE @Str2 NVARCHAR(MAX);
SELECT @Str = STUFF(
                  (
                      SELECT DISTINCT
                              ','+QUOTENAME(Period)
                      FROM dbo.testPeriods FOR XML PATH('')
                  ), 1, 1, '');
PRINT @Str
SET @str2 = N'select * from (
  select Period,account,Amount
  from dbo.testPeriods
  )x
  PIVOT
  (
  sum(amount) FOR Period in ('+@Str+')
  ) as p';
PRINT @Str2;
EXEC (@Str2);


Dette er en løsning, som kun tager de perioder med du har. Du kan også indsætte et where filter på din periode, så du kun får det du vil have. Det essentielle er at den kun tager de perioder som du selv angiver i din stuff. Jeg ved ikke om din period er som den står 2018M1 fx eller om det rent faktisk er et dato felt. Jeg har tilladet mig at lave det som en string her i dette eksempel

Resultatet af ovenstående query:

account    2018M1    2018M2    2018M3
25                    10    NULL    NULL
30              NULL    30            NULL
35              NULL    20            NULL
40                  20    NULL    NULL
90                  50    100            50

Og lige en ekstra side note-. Hvis du vil have null replacet med 0 skal du gøre sådan her

DECLARE @Str NVARCHAR(MAX);
DECLARE @Str2 NVARCHAR(MAX);
DECLARE @StrCol NVARCHAR(MAX);

SET @StrCol =  STUFF(
                  (
                      SELECT DISTINCT
                            -- ',ISNULL('+QUOTENAME(Period)+',0) AS ' +QUOTENAME(Period)
                              ','+QUOTENAME(Period)
                      FROM dbo.testPeriods FOR XML PATH('')
                  ), 1, 1,'');
SELECT @Str = STUFF(
                  (
                      SELECT DISTINCT
                              ',ISNULL('+QUOTENAME(Period)+',0) AS ' +QUOTENAME(Period)
                              --','+QUOTENAME(Period)
                      FROM dbo.testPeriods FOR XML PATH('')
                  ), 1, 1,'');


PRINT @Str
PRINT @StrCol

SET @str2 = N'select Account,'+@Str+' from (
  select Period,account,Amount
  from dbo.testPeriods
  )x
  PIVOT
  (
  sum(amount) FOR Period in ('+@StrCol+')
  ) as p';
PRINT @Str2;
EXEC (@Str2);