Trimme adresser og separere husnummer i egen celle

Ja, det kan man godt. Men det vil nok aldrig være 100% sikkert, og det er afhængigt af nogle antagelser.

Hvis man definerer gaden som "al tekst indtil første tal, minus blanke i enderne", så kan den findes med

=TRIM(LEFT(A1;MIN(FIND({0;1;2;3;4;5;6;7;8;9}; A1&"0123456789"))-1))

Hvils man definerer husnummeret som "det tal, der står først", så kan det findes med

=TRIM(LEFT(RIGHT(A1;LEN(A1)-MIN(FIND({0;1;2;3;4;5;6;7;8;9}; A1&"0123456789"))+1);MATCH(TRUE;ISERROR(VALUE(MID(RIGHT(A1;LEN(A1)-MIN(FIND({0;1;2;3;4;5;6;7;8;9}; A1&"0123456789"))+1);ROW(INDIRECT("1:"&LEN(RIGHT(A1;LEN(A1)-MIN(FIND({0;1;2;3;4;5;6;7;8;9}; A1&"0123456789"))+1))));1)));0)-1))

Men er det godt nok? Prøv eksempelvis at starte med et tal (hvis du fx er englænder, skriver du husnumeret først) - så virker formlen pludselig ikke.

mener der er en gade der hedder Christian 4. vej ups

måske noget med at:
1.  finde første tal fra højre
smide alt til højre herfor væk
2. finde første bogstav fra højre og til venstre her for må være navn og alt til højre må være nummer

God pointe!

Et problem er, at "første tal fra højre" nogen gange vil give etagen

Der er også nogen, der bor Christian 4. vej 5, 6 mf

Ikke let!

hvad med at finde fra højre mod venstre første bogstav efter et ciffer og se om der er et ciffer før, da der så skal ledes længere mod venstre efter et bogstav (husnummer 7A) så må stedet hvor skillelinjen mellem navn og nummer være fundet

Måske? Kan ikke helt gennemskue dit forslag. men hvis du kommer med formlen, er jeg frisk på at teste den

mon tekst til kolonner kan bruges?

"Tekst til kolonner" kan i hvert fald ikke finde det første 3-tal i "Cort Adelers gade3, 3, Tv.", men det er nok en typo, at der mangler et mellemrum.

Du vil dog stadig have det problem, at du skal vælge hvilke kolonner, du skal bruge.

Tænker bare så bliver det muligt at teste fra højre mod venstre og kombinere de celler der indeholder dele af navnet og tage cellen med nr.
hvis der er droppet mellemrum må man manuelt bearbejde de adresser.

Jeg har forsøgt mig med et alternativ, der koncentrerer sig omkring kommaet, der kommer umiddelbart efter husnummeret.
Måske det kan bruges:

Husnr: =HVIS.FEJL(HØJRE(VENSTRE(A1;SØG(",";A1;1)-1);3)*1;HVIS.FEJL(HØJRE(VENSTRE(A1;SØG(",";A1;1)-1);2)*1;HØJRE(VENSTRE(A1;SØG(",";A1;1)-1);1))*1)

Vejnavn:
=VENSTRE(A1;SØG(C1&",";A1)-1) , hvor C1 refererer til Husnummeret ovenfor.

Vh
Anedi

Og så godt bud!

Men hverken den eller min egen #1 virker på "Cort Adelers gade 3". Det kan godt løses ved blot at sætte et "," bagved i formlen.

Tror din er mere driftssikker, fordi den tillader tal i vejnnavnet.

Så mangler vi bare at høre fra lakrije

Det havde jeg i min iver slet ikke taget stilling til.

Husnummeret kan i så fald klares med denne:
=HVIS.FEJL(HØJRE(VENSTRE(A1;SØG(",";A1;1)-1);3)*1;HVIS.FEJL(HØJRE(VENSTRE(A1;SØG(",";A1;1)-1);2)*1;HVIS.FEJL(HØJRE(VENSTRE(A1;SØG(",";A1;1)-1);1)*1;HVIS.FEJL(HØJRE(A1;3)*1;HVIS.FEJL(HØJRE(A1;2)*1;HVIS.FEJL(HØJRE(A1;1)*1;""))))))

og Vejnavnet med:
=VENSTRE(A1;SØG(C1;A1)-1)

Vh
Anedi

Ja, eller erstat A1 med A1&"," i dine formler

Vejnavn:
=VENSTRE(A2;LÆNGDE(VENSTRE(A2;FIND(",";A2&",")-1))-(LÆNGDE(HØJRE(VENSTRE(A2;FIND(",";A2&",")-1);LÆNGDE(VENSTRE(A2;FIND(",";A2&",")-1))-FIND("*";UDSKIFT(VENSTRE(A2;FIND(",";A2&",")-1);" ";"*";LÆNGDE(VENSTRE(A2;FIND(",";A2&",")-1))-LÆNGDE(UDSKIFT(VENSTRE(A2;FIND(",";A2&",")-1);" ";""))))))+1))

Vej Nr:
=HØJRE(VENSTRE(A2;FIND(",";A2&",")-1);LÆNGDE(VENSTRE(A2;FIND(",";A2&",")-1))-FIND("*";UDSKIFT(VENSTRE(A2;FIND(",";A2&",")-1);" ";"*";LÆNGDE(VENSTRE(A2;FIND(",";A2&",")-1))-LÆNGDE(UDSKIFT(VENSTRE(A2;FIND(",";A2&",")-1);" ";"")))))

Tror de virker i 99 %