Hjælp til gøre det perfekt

Hej Mefa

Prøv med nedenstående.
Om den virker som den skal, afhænger af hvordan formlen udregnes i C5:

= TEKST(DATO(MIDT(A5;7;4);MIDT(A5;4;2);VENSTRE(A5;2));)  &
TEKST(DATO(MIDT(A5;7;4);MIDT(A5;4;2);VENSTRE(A5;2));" d. mmmm åååå")&" til" &TEKST(DATO(MIDT(B5;7;4);MIDT(B5;4;2);VENSTRE(B5;2));) &
TEKST(DATO(MIDT(B5;7;4);MIDT(B5;4;2);VENSTRE(B5;2));" d. mmmm åååå,") &  " i alt " & RUND.NED(C5;0)&" uger og " & RUND.NED((C5-RUND.NED(C5;0))*7;0) & " dage"

Hvad har du præcist i A5, B5 og C5 (dato eller tekst), og hvad ønsker du?

A5 og b5 er tekst og i c5 står

=ANTAL.ARBEJDSDAGE(A5;B5)/5

Jeg gerne have at der efter perioderne står 20 uger og 2 dage

Skift den sidste del
& C5 &" uger."
ud med
&HELTAL(C5/5)&" uger og "&(C5/5-HELTAL(C5/5))*5&" dage"

Som spurgt, præcist hvad står der i A5 og B5, og er der ikke mulighed for at det kan være rigtige datoer i stedet for tekst?

Som xl skriver, ville det optimale være, at datoen ikke er tekst. Hvis der ikke er vej udenom, kan du prøve flg.

OBS på at formlen kræver Excel 365

Du kan erstatte kolonne C5 med den her (medmindre du selvfølgelig gerne vil beholde den) :)

=LET(fra;DATO(MIDT(A5;7;4);MIDT(A5;4;2);VENSTRE(A5;2));
til;DATO(MIDT(B5;7;4);MIDT(B5;4;2);VENSTRE(B5;2));
periode;ANTAL.ARBEJDSDAGE(fra;til);
uger;HELTAL(periode/5);
dage;AFRUND(REST(periode/5;1);0);
TEKST(fra;"d. mmmm åååå")&" til "&TEKST(til;"d. mmmm åååå")&" i alt "&uger&" uger og "&dage&" dage")

Stig næsten rigtigt bortset fra der er 20 uger og 2 dage i mellem den 17.04.2023 og 05.09.2023.

jens-48

Perfekt bortset dagene er 1,99999999999 dage. Ville gerne at der stod 2 dage :) 😀 😃

Mellem 17-04-2023 og 05-09-2023 er der 141 dage = 20,142857 uger (=DATEDIF(A2;B2;"d")/7 hvis A2 og B2 indeholder rigtige datoer), hvilket jeg får til 20 uger og 1 dag.

Prøv med dette i stedet

&HELTAL(C5/5)&" uger og "&REST(C5;5)&" dage"

jens-48

Næsten perfekt men for mange decimaler i dagene.

Indtil videre går jeg med denne løsning og udfylder selv dagene

= TEKST(DATO(MIDT(A5;7;4);MIDT(A5;4;2);VENSTRE(A5;2));)  &
TEKST(DATO(MIDT(A5;7;4);MIDT(A5;4;2);VENSTRE(A5;2));" d. mmmm åååå")&" til" &TEKST(DATO(MIDT(B5;7;4);MIDT(B5;4;2);VENSTRE(B5;2));) &
TEKST(DATO(MIDT(B5;7;4);MIDT(B5;4;2);VENSTRE(B5;2));" d. mmmm åååå,") &  " i alt "  & C5 &" uge(r) "  & "og  " &" "& " dag(e)"

Det er kun en "lommeregner" og skal kopieres videre til et andet program.

Hvis du stadig har problemer med for mange decimaler, kan du ændre den sidste del til

&HELTAL(C5/5)&" uger og "&AFRUND(REST(C5;5);0)&" dage"

jens-48

1000 tak. Så fungerer det.