At læse og sortere indholdet fra en tekstfil

Jeg ville nok kaste dine linje ind i et Array, og så bagefter oprette endnu et Array til dine Vareoplysninger. Fx.

Array Linjer...
  Array varoplysninger...

//>Rune

Den ide har jeg selv fået. Men problemet er, at jeg gerne skulle have sorteret disse arrays. Det er den tricky del eftersom tekstfilen er lavet således, at varegruppen kan fremkomme gentagende gange i adskilte blokke hvis du forstår... Hvis arrayet skal gennemløbes og præsenteres på siden må kategorien ikke fremkomme mere end en gang og skal helst være alfabetisk sorteret.

set FSO = Server.CreateObject("Scripting.FileSystemObject")
set readfile = FSO.OpenTextFile("c:\somefile2.txt", 1, false)
indhold = readfile.ReadAll
readfile.close
arrindhold = split(indhold,"#")
set fso = nothing
for i = 0 to ubound(arrindhold) step 4
response.write arrindhold(i) & "<br>"
next

Sortering af dit array:

http://activedeveloper.dk/julekalender/julegaver/bubble.asp

/askhoej

måske en lidt bedre løsning ...

set FSO = Server.CreateObject("Scripting.FileSystemObject")
fil = server.mappath("text.txt")

set readfile = FSO.OpenTextFile(fil, 1, false)
do until readfile.AtEndOfStream
indhold = indhold & readfile.readline
loop

readfile.close
arrindhold = split(indhold,"#")
set fso = nothing
for i = 0 to ubound(arrindhold)
response.write arrindhold(i) & "<br>"
next

textfil indhold .:
hej#
med#
dig#
hej#
med#
dig#

kode .:
set FSO = Server.CreateObject("Scripting.FileSystemObject")
fil = server.mappath("text.txt")

set readfile = FSO.OpenTextFile(fil, 1, false)
do until readfile.AtEndOfStream
indhold = indhold & readfile.readline
loop

readfile.close
arrindhold = split(indhold,"#")
set fso = nothing
for i = 0 to ubound(arrindhold) -1 step 3
response.write arrindhold(i) & "<br>"
response.write arrindhold(i+1) & "<br>"
response.write arrindhold(i+2) & "<br>"
next

output.:
hej
med
dig
hej
med
dig

Det er skam fint nok... Men sæt nu værdierne optræder flere gange i digkolonnen. Den skal kun printe værdien første gang, men tage resten af kolonnerne med i pågældende linie og sortere hvad der nu kommer i denne kolonne alfabetisk? ;-)

hmm alfebetisk, ved jeg ikke engang om man kan når det komemr fra en text fil..hummm

Hurtigt og utestet:

--------------------------------------
data.txt indeholder:

#1#...#Bøger#43kr
#1#...#Skibe#43kr
#1#...#Bøger#43kr
#1#...#Skibe#43kr
#1#...#Bøger#43kr
#1#...#Heste#43kr
#1#...#Grise#43kr
#1#...#Bøger#43kr
#1#...#Penalhuse#43kr
#1#...#Bøger#43kr
#1#...#Bøger#43kr
#1#...#Bøger#43kr
#1#...#Penalhuse#43kr
#1#...#Bøger#43kr
#1#...#Bøger#43kr

--------------------------------------
kode:

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">

<html>
<head>
    <title>Eksperten 256109</title>
</head>

<body>
<%
set FSO = Server.CreateObject("Scripting.FileSystemObject")
fil = server.mappath("data.txt")

set readfile = FSO.OpenTextFile(fil, 1, false)

strFile = ""
do until readfile.AtEndOfStream
    strFile = strFile & readfile.readline & "¤"
loop

readfile.close
set fso = nothing

arrLines = Split(strFile,"¤")
antal = 100 'antal linier i datafil
ReDim arrVarekategorier(0,antal)

Dim arrLine
For i = 0 To UBound(arrLines)
    arrLine = Split(arrLines(i),"#")
   
    for j=3 To Ubound(arrLine)-1
        arrVarekategorier(0,i) = arrLine(j)
    Next

Next

Call BubbleSort(arrVarekategorier, 0, 0)

prevKategori = ""
for i = 0 to ubound(arrVarekategorier,2)

    if Len(arrVarekategorier(0,i)) > 0 AND NOT prevKategori = arrVarekategorier(0,i) Then
        response.write arrVarekategorier(0,i) & "<br>"
    End If
    prevKategori = arrVarekategorier(0,i)
   
next

Private Sub BubbleSort(byRef arrTemp, byVal sDim, byVal sSort)

' ======================================================================
' Name:        BubbleSort
' Arguments:    arrTemp = The array you want to be sorted
'    sDim = The dimension you want to sort for
'        sSort = Asc (0) OR Desc (1)
' Returns:    A sorted array
' Developer:    Dennis Knappe (dennis@activeserverpages.dk)
'
' This sourcecode can only be used if you DO NO remove my name and e-mail
' ======================================================================

    Dim n
    Dim y
    Dim t
    Dim tmpTop
    Dim tmpVal
    Dim iBookMark
    Dim BubbleElement

    BubbleElement = False

    For n = 0 To UBound(arrTemp,2)
        tmpTop = arrTemp(sDim,n)
        iBookmark = n

        For y = n To UBound(arrTemp,2)
            If sSort = 0 Then
                If (tmpTop > arrTemp(sDim,y)) Then
                    BubbleElement = True
                End If
            Else
                If (tmpTop < arrTemp(sDim,y)) Then
                    BubbleElement = True
                End If
            End If

            If BubbleElement Then
                tmpTop = arrTemp(sDim,y)
                iBookmark = y
                BubbleElement = False
            End If
        Next

        For t = 0 to UBound(arrTemp, 1)
            tmpVal = arrTemp(t, n)
            arrTemp(t, n) = arrTemp(t, iBookmark)
            arrTemp(t, iBookmark) = tmpVal
        Next
    Next

End Sub
%>


</body>
</html>

---------------------------------------
/askhoej