Paging med SQL server

Denner er paging af recordset....

http://activedeveloper.dk/aspdigital/kapitel2/paging.asp

Det skulle også virker med en SQL Server, bare ændre Connection fra Access til SQL server.

Dette er vel med SQL connection i stedet, det virker ik så vidt jeg kan se, tror det er noget med den åbning den laver til SQL man ikke kan på samme måde?

<%
intPage = Request("page")
If isNumeric(intPage) = False Or intPage < 1 Then
    intPage = 1
End If

Set rs = Server.CreateObject("ADODB.RecordSet")
strSQL = "SELECT * FROM tabel"
strDSN = "DRIVER=SQL Server; SERVER="&sname&"; UID="&usID&"; PWD="&pswd&"; DATABASE="&db&";"
rs.Open strSQL, strDSN, 1
If Not (rs.BOF Or rs.EOF) Then
    rs.PageSize = 10
    rs.AbsolutePage = intPage
    intRecCount = rs.PageSize
    intPageCount = rs.PageCount
    Response.Write "<p><b>Side " & intPage & " af " & intPageCount & "</b></p>"

    Do While Not rs.EOF And intRecCount > 0
        Response.Write rs("felt") & "<br>"
    intRecCount = intRecCount - 1
    rs.MoveNext
    Loop

End If
rs.Close
Set rs = Nothing

Response.Write "<p>Gå til side "
For intNum = 1 To intPageCount
    Response.Write "<a href=paging.asp?page=" & intNum & ">" & intNum & "</a> "
Next

Response.Write "<p>"
If Clng(intPage) > 1 Then
    Response.Write "<a href=paging.asp?page=" & intPage - 1 & ">&lt;&lt;</a>"
Else
    Response.Write "&lt;&lt;"
End If

Response.Write "&nbsp;"

If Clng(intPage) < Clng(intPageCount) Then
    Response.Write "<a href=paging.asp?page=" & intPage + 1 & ">&gt;&gt;</a> "
Else
    Response.Write "&gt;&gt;"
End If
%>

Hvis du ændre denne linie:

strDSN = "DRIVER=SQL Server; SERVER="&sname&"; UID="&usID&"; PWD="&pswd&";

Til dette:

Set Conn = Server.CreateObject("ADODB.Connection")
DSN = "DRIVER=SQL Server; SERVER="&sname&"; UID="&usID&"; PWD="&pswd&"; DATABASE="&db&";"
Conn.Open DSN


og denne linie:
rs.Open strSQL, strDSN, 1

TiL:
rs.Open strSQL, Conn, 1

Det' godkendt ;-)