størrelse af folder inkl, ALT

Jeg lavede den her kode til et lignende spørgsmål for nogle måneder siden:

Imports System
Imports System.IO

Module Main
    Sub Main()
        Console.WriteLine(total("C:\WINNT"))
    End Sub
    Function total(dir As String) As Integer
        Dim res As Integer = 0
        Dim i As Integer
        Dim d As DirectoryInfo = new DirectoryInfo(dir)
        Dim allf As FileInfo() = d.GetFiles()
        For i = 0 To allf.Length - 1
            res = res + allf(i).Length
        Next
        Dim alld As DirectoryInfo() = d.GetDirectories()
        For i = 0 To alld.Length - 1
            res = res + total(alld(i).FullName)
        Next
        total = res
    End Function
End Module

Du bliver nødt til at køre folderen gennem rekursivt:

Fra: http://msdn.microsoft.com/library/default.asp?url=/library/en-us/cpref/html/frlrfsystemiodirectoryclasstopic.asp

[Visual Basic]
' The following example calculates the size of a directory
' and its subdirectories, if any, and displays the total size
' in bytes.
Imports System
Imports System.IO
Imports Microsoft.VisualBasic



Public Class ShowDirSize

    Public Shared Function DirSize(ByVal d As DirectoryInfo) As Long
        Dim Size As Long = 0
        ' Add file sizes.
        Dim fis As FileInfo() = d.GetFiles()
        Dim fi As FileInfo
        For Each fi In fis
            Size += fi.Length
        Next fi
        ' Add subdirectory sizes.
        Dim dis As DirectoryInfo() = d.GetDirectories()
        Dim di As DirectoryInfo
        For Each di In dis
            Size += DirSize(di)
        Next di
        Return Size
    End Function 'DirSize

    Public Overloads Shared Sub Main(ByVal args() As String)
        If args.Length <> 1 Then
            Console.WriteLine("You must provide a directory argument at the command line.")
        Else
            Dim d As New DirectoryInfo(args(0))
            Console.WriteLine("The size of {0} and its subdirectories is {1} bytes.", d, DirSize(d))
        End If
    End Sub 'Main
End Class 'ShowDirSize

Lukke tid ?

Og et svar