Forskellige farver tekst i Stringgrid

Prøv det her:

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  with (Sender as TStringGrid) do
  begin
    if (ACol = 1) and (ARow = 1) then
    begin
      Canvas.Font.Color := clRed;
      Canvas.TextRect(Rect, Rect.Left + 2, Rect.Top + 2, cells[acol, arow]);
      Canvas.FrameRect(Rect);
    end;
  end;
end;

Det gør den første celle i Stringgrid'en rød.

bliver det ikke hveranden linie?

stone -> Neej, det er kun den første celle, teksten bliver rød i :)

to ting:

1. det bliver den anden celle i den anden række der bliver rød,

2. hvis man ikke husker at sætte defaultdrawing for stringgrid'et til false er der slet ingen celler der bliver røde ;)

ha' det godt
hatecaps

hatecaps -> Er det ikke ligemeget om sætter DefaultDrawing til False, ved mig virker det ihvertfald aligevel, den eneste forskel der er, at den med DefaultDrawing kun tegner stegerne for celerne :o)

er der en anden måde at gøre det på, for det virker ikke for mig ? skal jeg køre proceduren nogen steder eller hvordan ?

hmm.. nu virker det... skulle jo bare lige lave det ordentligt, men skal egentlig have det i en funktion, for jeg er ved at lave en kalender der viser 3 måneder. 1 måned i hver række. Og det er så hver celle som indeholder søndag der skal have rød text, og da det jo ikke er samme celle i alle 3 rækker så kan jeg jo ikke bruge denne procedure... Nogen forslag ?

Måske virker det her lidt bedre :o)

type
  TForm1 = class(TForm)
    ...
  private
    procedure SetCellTextColor(X, Y: Integer; Color: TColor);
    ...
  end;

var
  Form1: TForm1;
  Colors: array of array of TColor;

implementation

{$R *.dfm}

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  with (Sender as TStringGrid) do
  begin
    Canvas.Font.Color := Colors[ACol, ARow];
    Canvas.TextRect(Rect, Rect.Left + 2, Rect.Top + 2, Cells[ACol, ARow]);
    Canvas.FrameRect(Rect);
  end;
end;

procedure TForm1.SetCellTextColor(X, Y: Integer; Color: TColor);
begin
  Colors[X, Y] := Color;
  StringGrid1.Repaint;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  I, J: Integer;
begin
  SetLength(Colors, StringGrid1.ColCount);
  for I := Low(Colors) to High(Colors) do
  begin
    SetLength(Colors[I], StringGrid1.RowCount);
    for J := Low(Colors[I]) to High(Colors[I]) do
      Colors[I, J] := clBlack;
  end;
end;

Så sætter du farven på en celle med f.eks. SetCellTextColor(1,2, clRed);.

det virker skide godt :) takker.. men kan man også lave det så man kan ændre baggrundsfarven i en bestemt celle ?

Ja, det kan man :o)... Prøv det her:

type
  TForm1 = class(TForm)
    ...
  private
    procedure SetCellTextColor(X, Y: Integer; Color: TColor);
    procedure SetCellColor(X, Y: Integer; Color: TColor);
    ...
  end;

var
  Form1: TForm1;
  Colors: array of array of TColor;
  Colors2: array of array of TColor;

implementation

{$R *.dfm}

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  with (Sender as TStringGrid) do
  begin
    Canvas.Font.Color := Colors[ACol, ARow];
    Canvas.Brush.Color := Colors2[ACol, ARow];
    Canvas.TextRect(Rect, Rect.Left + 2, Rect.Top + 2, Cells[ACol, ARow]);
    Canvas.FrameRect(Rect);
  end;
end;

procedure TForm1.SetCellTextColor(X, Y: Integer; Color: TColor);
begin
  Colors[X, Y] := Color;
  StringGrid1.Repaint;
end;

procedure TForm1.SetCellColor(X, Y: Integer; Color: TColor);
begin
  Colors2[X, Y] := Color;
  StringGrid1.Repaint;

procedure TForm1.FormCreate(Sender: TObject);
var
  I, J: Integer;
begin
  SetLength(Colors, StringGrid1.ColCount);
  for I := Low(Colors) to High(Colors) do
  begin
    SetLength(Colors[I], StringGrid1.RowCount);
    for J := Low(Colors[I]) to High(Colors[I]) do
      Colors[I, J] := clBlack;
  end;

  SetLength(Colors2, StringGrid1.ColCount);
  for I := Low(Colors2) to High(Colors2) do
  begin
    SetLength(Colors2[I], StringGrid1.RowCount);
    for J := Low(Colors2[I]) to High(Colors2[I]) do
      Colors2[I, J] := clBlack;
  end;
end;

Har ikke haft mulighed for at teste det, men tror det virker :o)

kanon det virker perfekt.. kan du ikke lige smide et par kommentarer til linierne så jeg helt ved hvad der sker hvis jeg nu skulle forklare det til en anden ?

Ellers så smid et svar så får du point.

Du må undskylde jeg har været lidt langsom, men overså mailen med dit indlæg :(

Har prøvet at foreklare lidt af koden, hvis der er noget du ikke forstår kan du bare spørge. De fleste af funktionerne kan du finde en forklaring på, i Delphi' hjælp :o)

  Colors: array of array of TColor;//Et multidimensional array til at holde tekst farven på alle cellerne
  Colors2: array of array of TColor;//Et multidimensional array til at holde baggrundsfarven på alle cellerne

implementation

{$R *.dfm}

//DrawCell bliver kaldt hver gang en celle bliver "tegnet"
procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  with (Sender as TStringGrid) do
  begin
    Canvas.Font.Color := Colors[ACol, ARow];    //Sætter farven på skriften
    Canvas.Brush.Color := Colors2[ACol, ARow];    //Sætter baggrundfarven
    Canvas.TextRect(Rect, Rect.Left + 2, Rect.Top + 2, Cells[ACol, ARow]); //Tegner teksten i cellen med den nye farve
    Canvas.FrameRect(Rect);    //Tegner en ramme omkring cellen
  end;
end;

procedure TForm1.SetCellTextColor(X, Y: Integer; Color: TColor);
begin
  Colors[X, Y] := Color;
  StringGrid1.Repaint;//Opdatere stringgrid'en
end;

procedure TForm1.SetCellColor(X, Y: Integer; Color: TColor);
begin
  Colors2[X, Y] := Color;
  StringGrid1.Repaint;//Opdatere stringgrid'en
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  I, J: Integer;
begin
  SetLength(Colors, StringGrid1.ColCount);
  for I := Low(Colors) to High(Colors) do
  begin
    SetLength(Colors[I], StringGrid1.RowCount);
    for J := Low(Colors[I]) to High(Colors[I]) do
      Colors[I, J] := clBlack;//Sætter standard tekst farven til sort
  end;

  SetLength(Colors2, StringGrid1.ColCount);
  for I := Low(Colors2) to High(Colors2) do
  begin
    SetLength(Colors2[I], StringGrid1.RowCount);
    for J := Low(Colors2[I]) to High(Colors2[I]) do
      Colors2[I, J] := clWhite;//Sætter standard baggrundsfarven til hvid
  end;
end;

skide godt :) takker