Beregning af tid, som falder imellem 2 tidspunkter i en periode

time1 = date() &" "& right("02/20/2005 16:00",5)
time2 = date() &" "& right("02/28/2005 19:00",5)

datediff("n",time1,time2)

//Fennec

Hvorfor tar du med date() samt right og 5 tegn?

Bare lurer.
//Morten

Var ikke sikker på hvordan den ville opføre sig, hvis den kun fik time/min tallet. Så jeg ville gør det til en rigtig dato.

Gik desuden ud fra at jqp får de forskellige datoer/tider fra en variabel, også bruger jeg right funktionen til at pille time/min ud, og smide dem i en ny variabel.

Fennec: Så vidt jeg umiddelbart kan se, kigger de løsnige udelukkede på hvor lang tid der er imellem tiderne på de 2 timestamps.

Den vil ikke tage højde for om tiden ligger inden for Tidsrummet. Den vil ikke tage højde for at perioden går over flere søndage.

Desvære.

... Så er jeg ikke med på hvad du ønsker. Kan du forklare det anderledes???

Jeg kan da prøve:

Du ser fodbold hver søndag imellem 15:00 og 18:00. Jeg kunne godt tænke mig en funktion, der kan beregne hvor mange minuters fodbold du så i perioderne 2004-01-01 til 2004-12-31 og 2005-02-01 til 2005-02-28.

Håber det afklare opgaven.

Så er jeg med, men hvordan det skal gøres er jeg ikke sikker på.

Tidsrummet kan det godt gå over flere dage?? Hvis man f.eks ser TV fra lørdag 22:00 til søndag 02:00 eller helt ekstrem fre 23:00 til søn 10:00.

Fik lavet denne her funktion, som gerne skulle kunne klare det:

Response.Write calcServiceWindow("06-03-2005 16:00:00", "13-03-2005 19:00:00", "15:00:00", "18:00:00", vbSunday)
'** Calculate Service Window in minutes (SW) - SW is a specific timespan on a weekday **'
  Function calcServiceWindow(timestampStart, timestampEnd, SWstart, SWend, SWday)
    Dim countSWdays, FirstSundayDiff, LastSundayDiff, DaysInPeriod, SWlength
    DaysInPeriod = DateDiff("d", timestampStart, timestampEnd)
    SWlength = DateDiff("n", SWstart, SWend)
    countSWdays = 0

    '** Get number of SWday's in period **'
    If DaysInPeriod => 1 Then
      countSWdays = Int(DaysInPeriod / 7)
      '** If =>8, period must contain an extra SWday Or If 1, period end and start on SWday **'
      If (Weekday(timestampStart) + DaysInPeriod Mod 7) => 8 Or Weekday(timestampStart) = SWday Then countSWdays = countSWdays + 1
    End If

    '** If first or last date is a SWday **'
    If DatePart("w", timestampStart, SWday) = 1 Then
      '** Are period only one day? **'
      If DateDiff("d", timestampStart, timestampEnd) = 0 And DateDiff("n", FormatDateTime(timestampEnd, 3), SWend) > 0 Then
        If DateDiff("n", FormatDateTime(timestampStart, 3), SWstart) < 0 Then
          FirstSundayDiff = DateDiff("n", FormatDateTime(timestampStart, 3), FormatDateTime(timestampEnd, 3))
        Else
          FirstSundayDiff = DateDiff("n", SWstart, FormatDateTime(timestampEnd, 3))
        End If
      Else '** Period is more than one day
        FirstSundayDiff = DateDiff("n", FormatDateTime(timestampStart, 3), SWstart)
        If FirstSundayDiff > 0 Then FirstSundayDiff = 0 : countSWdays = countSWdays + 1 '** Full SW
        If FirstSundayDiff < (SWlength*-1) Then FirstSundayDiff = 0 '** Starts after SW ends
        If FirstSundayDiff <> 0 Then FirstSundayDiff = SWlength - (FirstSundayDiff*-1) '** Some SW
        countSWdays = countSWdays -1
      End If
    End If
    If DatePart("w", timestampEnd, SWday) = 1 And DateDiff("d", timestampStart, timestampEnd) > 0  Then
      LastSundayDiff = DateDiff("n", SWend, FormatDateTime(timestampEnd, 3))
      If LastSundayDiff > 0 Then LastSundayDiff = 0 : countSWdays = countSWdays + 1 '** Full SW
      If LastSundayDiff < (SWlength*-1) Then LastSundayDiff = 0 '** Ends before SW starts
      If LastSundayDiff <> 0 Then LastSundayDiff = SWlength - (LastSundayDiff*-1) '** Some SW
      countSWdays = countSWdays -1
    End If
    calcServiceWindow = (SWlength * countSWdays) + Abs(FirstSundayDiff) + Abs(LastSundayDiff)
  End Function

fennec: Som du kan se, kan man PT ikke se fodbold hen over midnat. Eller funktionen kan i hvert fald ikke finde ud af det :-) Tak for hjælpen

Det var nu ikke så meget hjælp jeg fik givet :o)

Fandt et par fejl, denne version skulle gerne være mere fejlfri:

Function calcServiceWindow(timestampStart, timestampEnd, SWstart, SWend, SWday)
    Dim countSWdays, FirstSundayDiff, LastSundayDiff, DaysInPeriod, SWlength, tmpSWstart, tmpSWend
    DaysInPeriod = DateDiff("d", timestampStart, timestampEnd)
    SWlength = DateDiff("n", SWstart, SWend)
    countSWdays = 0

    '** Get number of SWday's in period **'
    countSWdays = Int(DaysInPeriod / 7)
    '** If =>8, period must contain an extra SWday Or If 1, period end and start on SWday **'
    If (Weekday(timestampStart) + DaysInPeriod Mod 7) => 8 Or Weekday(timestampStart) = SWday Then countSWdays = countSWdays + 1

    '** If first or last date is a SWday **'
    If DatePart("w", timestampStart, SWday) = 1 Then
      If DateDiff("n", FormatDateTime(timestampStart, 3), SWend) < 0 Then '** X<XXX>O - Period starts after SW ends
        FirstSundayDiff = 0
      ElseIf DateDiff("n", FormatDateTime(timestampEnd, 3), SWstart) > 0 And _
            DaysInPeriod = 0 Then '** O<XXX>X - Period ends before SW starts
        FirstSundayDiff = 0
      ElseIf DateDiff("n", FormatDateTime(timestampStart, 3), SWstart) < 0 And _
            DateDiff("n", FormatDateTime(timestampEnd, 3), SWend) > 0 And _
            DaysInPeriod = 0 Then '** X<XOX>X - Period starts before SW starts and ends before SW ends
        FirstSundayDiff = DateDiff("n", FormatDateTime(timestampStart, 3), FormatDateTime(timestampEnd, 3))
      ElseIf DateDiff("n", FormatDateTime(timestampStart, 3), SWstart) < 0 And _
            (DateDiff("n", FormatDateTime(timestampEnd, 3), SWend) < 0 Or _
            DaysInPeriod > 0) Then '** X<XOO>O - Period starts after SW starts and ends after SW ends
        FirstSundayDiff = DateDiff("n", FormatDateTime(timestampStart, 3), SWend)
      ElseIf DateDiff("n", FormatDateTime(timestampStart, 3), SWstart) > 0 And _
            DateDiff("n", FormatDateTime(timestampEnd, 3), SWend) > 0 And _
            DaysInPeriod = 0 Then '** O<OOX>X - Period starts before SW starts and ends before SW ends
        FirstSundayDiff = DateDiff("n", SWstart, FormatDateTime(timestampEnd, 3))
      ElseIf DateDiff("n", FormatDateTime(timestampStart, 3), SWstart) > 0 And _
            (DateDiff("n", FormatDateTime(timestampEnd, 3), SWend) < 0 Or _
            DaysInPeriod > 0) Then '** O<OOO>O - Period starts before SW starts and ends after SW ends
        FirstSundayDiff = SWlength
      End If
      countSWdays = countSWdays -1
    End If
    If DatePart("w", timestampEnd, SWday) = 1 And DateDiff("d", timestampStart, timestampEnd) > 0  Then
      LastSundayDiff = DateDiff("n", SWend, FormatDateTime(timestampEnd, 3))
      If LastSundayDiff > 0 Then LastSundayDiff = 0 : countSWdays = countSWdays + 1 '** Full SW
      If LastSundayDiff < (SWlength*-1) Then LastSundayDiff = 0 '** Ends before SW starts
      If LastSundayDiff <> 0 Then LastSundayDiff = SWlength - (LastSundayDiff*-1) '** Some SW
      countSWdays = countSWdays -1
    End If
    calcServiceWindow = (SWlength * countSWdays) + Abs(FirstSundayDiff) + Abs(LastSundayDiff)
  End Function

En noget bedre funktion. Løsningen er baseret på en løsning modtaget fra en anden "hjælpe" side:

Response.Write getSWminutes("06/03/2005 17:00", "13/03/2005 17:00", "15:00:00", "18:00:00", vbSunday)
Function getSWminutes(sd, ed, WindowStart, WindowEnd, WindowDay)
  Dim Windows : Windows = DateDiff("ww", sd, ed, WindowDay)
  Dim Interval : Interval = DateDiff("n", WindowStart, WindowEnd)
  If WeekDay(sd) = WindowDay Then Windows = Windows + 1
  getSWminutes = Windows * Interval - SWBoundary(sd, WindowStart, Interval, WindowDay, False) - SWBoundary(ed, WindowStart, Interval, WindowDay, True)
End Function

Function SWBoundary(d, WindowStart, Interval, WindowDay, LastDay)
  If WeekDay(d) = WindowDay Then
    SWBoundary = DateDiff("n",FormatDateTime(d,2) & " " & WindowStart,d)
    If SWBoundary < 0 Then SWBoundary = 0
    If SWBoundary > Interval Then SWBoundary = Interval
    If LastDay Then SWBoundary = Interval - SWBoundary
  Else
    SWBoundary = 0
  End If
End Function