Undgå dubletter i streng..

Function AddNumber(numbers, str)
    Dim check, aNum, aStr, i, j
    aNum = Split(numbers, ",")
    aStr = Split(str, ",")

    For i=0 To UBound(aNum)
        'kontroller om nummeret allerede eksisterer
        check = False
        For j=0 To UBound(aStr)
            If aNum(i) = aStr(j) Then
                check = True
                Exit For
            End If
        Next
       
        If Not Check Then
            str = str & "," & aNum(i)
        End If

    Next
    AddNumber = str
End Function

str = "1,2,3,4,6"
num = "1,8,9,10"
str = AddNumber(num, str)

Hvordan får jeg så udtrækket af den nye streng den har genererret ??

Det er ved at blive sent, jeg har fået det til at virke smid point det er dine ;)

Nå, nu havde jeg ellers lige en anden version som måske ville performe bedre med større datamængder... du får den lige alligevel :)

function mergeNumbers(strOriginal, strNewNumbers)
  ' Sæt komma omkring alle tallene for at gøre søgningen lettere
  strOrigNums = "," & strOriginal & ","
   
  ' Streng til at indeholde nye tal
  strNewExclusiveNums = ""
   
  ' Lav et array med alle de nye tal, så det er lettere at gennemløbe med et loop
  arrNewNumbers = Split(strNewNumbers, ",")
  for idx = 0 to ubound(arrNewNumbers)
    ' se om tallet eksisterer (sæt komma omkring for at sikre
    ' at det kun er hele tallet der findes)
    if instr(1, strOrigNums, "," & arrNewNumbers(idx) & ",") = 0 then
      ' Hvis tallet ikke eksisterer i forvejen gemmes det
      strNewExclusiveNums = strNewExclusiveNums & "," & arrNewNumbers(idx)
    end if
  next
   
  ' sammensæt de eksisterende tal med de nye og returner den nye streng af tal
  mergeNumbers = strOriginal & strNewExclusiveNums
end function

strNumbers = "1,5,8,12,15,19,20,21,32,56,67,77,78,79,80,82,83,84,85,87,88,89,90,91,92,93,94,95,96,97,98,99,100"
strNewNumbers = "1,5,6,78,89,90"
Response.Write "Merge " & strNumbers & " with " & strNewNumbers & "<br>"
Response.Write mergeNumbers(strNumbers, strNewNumbers)

I kan begge ligge et svar,

OK :)

Tak for point :)