Tvinge browseren til at downlode

Dét har jeg godt nok ikke set nogle scripts der kan.
Lige netop de filer der vil åbne Windows Media Player og begynde, at afspille dem.
Alle Mp3 sider beder netop derfor deres brugere om at højreklikke på linket og vælge gem som.

Hej

Hvis du vil tvinge browseren på den måde skal du hente filen binært.
- Jeg fandt lige dette script til dette:

<%@Language="VBScript"%>
<%Option Explicit%>
<%Response.Buffer = True%>
<%
On Error Resume Next
Dim strPath
strPath = CStr(Request.QueryString("file"))
'-- do some basic error checking for the QueryString
If strPath = "" Then
    Response.Clear
    Response.Write("No file specified.")
    Response.End
ElseIf InStr(strPath, "..") > 0 Then
    Response.Clear
    Response.Write("Illegal folder location.")
    Response.End
ElseIf Len(strPath) > 1024 Then
    Response.Clear
    Response.Write("Folder path too long.")
    Response.End
Else
    Call DownloadFile(strPath)
End If

Private Sub DownloadFile(file)
    '--declare variables
    Dim strAbsFile
    Dim strFileExtension
    Dim objFSO
    Dim objFile
    Dim objStream
    '-- set absolute file location
    strAbsFile = Server.MapPath(file)
    '-- create FSO object to check if file exists and get properties
    Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
    '-- check to see if the file exists
    If objFSO.FileExists(strAbsFile) Then
        Set objFile = objFSO.GetFile(strAbsFile)
        '-- first clear the response, and then set the appropriate headers
        Response.Clear
        '-- the filename you give it will be the one that is shown
        ' to the users by default when they save
        Response.AddHeader "Content-Disposition", "attachment; filename=" & objFile.Name
        Response.AddHeader "Content-Length", objFile.Size
        Response.ContentType = "application/octet-stream"
        Set objStream = Server.CreateObject("ADODB.Stream")
        objStream.Open
        '-- set as binary
        objStream.Type = 1
        Response.CharSet = "UTF-8"
        '-- load into the stream the file
        objStream.LoadFromFile(strAbsFile)
        '-- send the stream in the response
        Response.BinaryWrite(objStream.Read)
        objStream.Close
        Set objStream = Nothing
        Set objFile = Nothing
    Else 'objFSO.FileExists(strAbsFile)
        Response.Clear
        Response.Write("No such file exists.")
    End If
    Set objFSO = Nothing
End Sub
%>

her bliver filens navn og format så defineret i en querystring...

så et link til downloaden kunne se sådan her ud:
http://www.domain.dk/download.asp?file=DinFil.mp3

Det var mit bedste bud...

\Dan

Tak Dan! Det virker.

Jeg vil lige gøre opmærksom på, hvis der kommer en fejlmeddelse frem når filen skal til at blive hentet ned, er det fordi bufferen er begrænset. Som standard til ca. 4 mb!

....Dan smider du lige et svar!

Jamen det var da godt så!

- hermed et svar.

\Dan