Renek Novice
17. februar 2017 - 14:37 Der er 8 kommentarer og
1 løsning

Variabel beregning af flere celleværdier uden brug af VBA

Hej,

Havde svært ved at lave en passende overskrift så here goes:

Jeg har f.eks. følgende data i kolonne A (1-10 er rækkerne)

1    1,1
2    0,9
3
4    1,2
5    1,1
6    0,9
7
8
9    1,1
10

Jeg har brug for, uden brug af VBA, at beregne produktet af disse "øer" af data i kolonne B, så der skal være et resultat i B2, B6, og B9. Formlen skal f.eks. på en eller anden snedig måde i B5 sige "der er data i B4, men også i B6 så jeg skal ikke regne noget endnu" og så i B6 sige "Der er data i B5 og ingen data i B7 så nu skal jeg regne produktet af B6 og de celler bagved som indeholder data" - dvs 0,9*1,1*1,2.

Kan det mon løses?

Med venlig hilsen

René
kim1a Forsker
17. februar 2017 - 15:32 #1
Hej René

Det er lidt en storm P og jeg håber der er nogen som har en mere elegant løsning, men here goes. Vær opmærksom på at jeg testede ved at startede dine data i S13 i stedet for A1. Så kolonne S er 1-10 og kolonne T er dine decimaltal.

I Kolonne U:
=IF(T13<>0;IF(U12="";IF(U11="";IF(U10="";U9+1;U10+1);U11+1);U12);"")
Denne løsning har del fejl at der ikke må være mere end tre tomme huller efter hinanden i din decimaltal række.
Formlen gør at de ranges der er samlet får hver sit tal - så den første klump er 1, den næste er 2 etc.

Så i kolonnen ved siden af skriver du dette:
=IF(U13<>"";"";SUMIF(U:U;U12;T:T))

På den måde får du summer under hver klump - men dog i kolonner ved siden af. Hvis der er flere blanke felter imellem rækkerne skriver den blot 0 i disse.

Som sagt er fejlen at den indtil nu kun kan klare 3 tomme felter i rap - skal du have flere på, skal du udvide den første formel.
Renek Novice
17. februar 2017 - 16:10 #2
Hej Kim

Tak for hurtigt svar og forsøg på løsningen.

Desværre virker den ikke, da antallet af sammenhængende celler med og uden data er vidt forskelligt - jeg har et stort regneark ud over det lille eksempel jeg gav hvor data ligger i store klumper :/

God weekend!
jens48 Professor
17. februar 2017 - 17:14 #3
Hvis du laver en hjælpekolonne med denne formel i B1:

=IF(A1;1;0)

og denne formel i B2 og nedefter:

=IF(A2;B1+1;0)

kan du i C1 og nedefter skrive:

=IF(A1;PRODUCT(INDIRECT("A"&ROW()-B1+1&":A"&ROW()));)

På dansk bliver det:
=HVIS(A1;1;0)
=HVIS(A2;B1+1;0)
=HVIS(A1;PRODUKT(INDIREKTE("A"&RÆKKE()-B1+1&":A"&RÆKKE()));)
jens48 Professor
17. februar 2017 - 17:25 #4
Hvis du kun vil have vist værdien ud for sidste celle i hver gruppe, så ændr formelen i C1 til:

=IF(AND(A1<>0;NOT(A2));IF(A1;PRODUCT(INDIRECT("A"&ROW()-B1+1&":A"&ROW())););"")

Dansk:
=HVIS(OG(A1<>0;IKKE(A2));HVIS(A1;PRODUKT(INDIREKTE("A"&RÆKKE()-B1+1&":A"&RÆKKE())););"")
Renek Novice
17. februar 2017 - 18:25 #5
Hej Jens

Jeg er målløs over alle de kreative løsninger I er kommet med til alle mine dagligdagsopgaver med Excel igennem tiden, og din løsning virkede perfekt. Tak for det.

Jeg har ca 10.000 datapunkter, der skal beregnes, og det kan jeg så gøre nemt og elegant nu - uden fejl.

God weekend!
Renek Novice
17. februar 2017 - 18:52 #6
Ekstra spørgsmål her på falderebet Jens: Er der mulighed for at gøre "A" i denne formel variabel og ikke hard coded?:

=HVIS(OG(A1<>0;IKKE(A2));HVIS(A1;PRODUKT(INDIREKTE("A"&RÆKKE()-B1+1&":A"&RÆKKE())););"")

Jeg har mine data i en tabel med næsten 400 koloner så jeg har brug for at kunne trække den -  eventuelt ved at lade "A" pege på en lang række med stigende bogstavrække så den selv sørger for at skifte "A" ud med "B" og dernæst "C" når jeg trækker. Sikkert kluntet formuleret, men håber du forstår og har lyst til at kigge på det.

Mange hilsner

René
jens48 Professor
17. februar 2017 - 19:31 #7
Det kan godt lade sig gøre om end det bliver lidt mere kompliceret. Alle 3 formeler skal ændres. Jeg har flyttet hjælpekolonnen til kolonne O. Bogstavet der angiver hvilken kolonne der skal undersøges står i N1. De 2 formler for hjælpekolonnen kommer til at se således ud:

=IF(INDIRECT($N$1&1);1;0)
=IF(INDIRECT($N$1&ROW());O1+1;0)

Og i P1 og nedefter skriver jeg:

=IF(AND(INDIRECT($N$1&ROW())<>0;NOT(INDIRECT($N$1&ROW()+1)));IF(INDIRECT($N$1&ROW());PRODUCT(INDIRECT($N$1&ROW()-O1+1&":"&$N$1&ROW())););"")


På dansk:
=HVIS(INDIREKTE($N$1&1);1;0)
=HVIS(INDIREKTE($N$1&RÆKKE());O1+1;0)
=HVIS(OG(INDIREKTE($N$1&RÆKKE())<>0;IKKE(INDIREKTE($N$1&RÆKKE()+1)));HVIS(INDIREKTE($N$1&RÆKKE());PRODUKT(INDIREKTE($N$1&RÆKKE()-O1+1&":"&$N$1&RÆKKE())););"")
jens48 Professor
17. februar 2017 - 19:36 #8
Det var en alt for kompliceret løsning jeg lige kom med. Lav en indirekte funktion i kolonne A i stedet og bibehold resten
Renek Novice
17. februar 2017 - 20:21 #9
Fantastisk - mange mange tak for hjælpen!
Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links

Opret Preview

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester





CIO
Bliv klar til EU-persondataforordningen: Ministerium klar med længe ventet dansk vejledning til den nye EU-lov
Justitsministeriet er efter en måneds forsinkelse klar med den store vejledning til EU's kommende persondataforordning, der kommer til at få konsekvenser for alle danske virksomheder. Se vejledningen her.
Comon
Microsofts vilde - og hammerdyre - Surface Studio kommer til Danmark
Microsofts all-in-one-computer, Surface studio, kommer til Danmark midt i juni til en vild pris
Job & Karriere
Dansk it-firma masseansætter: Skal bruge 90 nye medarbejdere med disse it-profiler
It-virksomheden BEC skal bruge 90 nye it-medarbejdere. Her kan du se de konkrete it-profiler, BEC er på udkig efter.
White paper
8 grunde til hvorfor fremstilling og cloud hører sammen
Læs om de 8 grunde hvorfor fremstilling og cloud hører sammen