Loop fra 1 til 100, spring visse tal over

du kan lave et array med de 'forbudte' tal, og så cykle det igennem lige efter din Do while... hvis der ikke er hit der, så kører du response.write

og så skal post = "1" rettes til, så det er et tal, ikke en tekst, så post = 1 vil virke før loop

Jeg fandt dette:

Function InArray(Needle, Haystack)
            Dim i, x
            InArray = False

            For i = 0 To Ubound(Haystack)
                If IsArray(Needle) = True Then
                    For x = 0 To Ubound(Needle)
                        If Trim(Haystack(i)) = Trim(Needle(x)) Then
                            InArray = True
                            Exit Function
                        End If
                    Next
                Else
                    If Trim(Haystack(i)) = Trim(Needle) Then
                        InArray = True
                        Exit Function
                    End If
                End If
            Next
        End Function
        poster = Array(convertedstring)

Som virker rigtig fint, dog har jeg et problem med den liste jeg laver, der skal kontrolleres op i mod

Den laver jeg sådan:
liste = 0
        Set rs =  Server.CreateObject("ADODB.Recordset")
        strSQL = "SELECT * FROM poster "
        Set rs = Conn.Execute(strSQL)
        if rs.eof or rs.bof then
        else
        do until rs.eof or rs.bof
        liste = liste & "," & rs("postnr")
        rs.movenext
        loop
        end if
        rs.close
        Set rs = Nothing

Men værdierne bliver ignoreret, problemet er "" omkring mit , (tænker måske det er fordi listen så ikke er af numerisk værdi længere?)
Laver jeg en liste manuelt som liste = "0,4,5,10" virker det helt perfekt.

Kan du hjælpe med hvordan jeg kan løse dette?

Jeg ville overveje at bruge dictionary.

' opret dictionary
Set d = Server.CreateObject("Scripting.Dictionary")
' tilføj værdier (evt. fra database)
d.Add 2, "Drop"
d.Add 4, "Drop"
' loop og spring over dem i dictionary
for i = 1 to 6
    if not d.Exists(i) then
        ' lav noget me di
    end if
next

Super forslag arne_v - Det spiller

        ' opret dictionary
Set d = Server.CreateObject("Scripting.Dictionary")
' tilføj værdier (evt. fra database)
Set rs =  Server.CreateObject("ADODB.Recordset")
strSQL = "SELECT * FROM poster "
Set rs = Conn.Execute(strSQL)
if rs.eof or rs.bof then
else
do until rs.eof or rs.bof
d.Add rs("postnr").Value, "Drop"
rs.movenext
loop
end if
' loop og spring over dem i dictionary
for i = 1 to 200
    if not d.Exists(i) then
        response.write "<option value=""" & i & """>" & i & "</option>"
    end if
next

Tak for hjælpen begge

Bemærk at værdien  "Drop" ikke bruges. Den er dert kun fordi et Dictionary skal have både en key og en value. VBS (g dermed ASP) har ikke et Set object med kun key.