Tilføje søgeord?

Man kunne jo lave tabel med relation til Artikel ID, hvor der tilføjes de søgeord du vil have med !

Med mindre du ligefrem tilføjer artiklens klare tekst i notatform, så kan jeg ikke se at du har behov for flere søgekriterier

Hvorfor ikke lave en funktion, som kan søge på både overskrift og indholdsfeltet?

Du kan f.eks lave det således:

Private Sub SOEGBILLEDE_Click()
    Dim strSQL As String
    Dim strWhere As String
    Dim strOrderBy As String
 
    strSQL = "SELECT * " & _
            "FROM vw_main03 "
    strWhere = getWHEREclause
    strOrderBy = " ORDER BY Dato, Chef "
           
    Me.lstSearch.RowSource = strSQL & strWhere & strOrderBy
    Me.txtDato.SetFocus

End Sub

Private Function getWHEREclause() As String
    Dim strWhereDato As String
    Dim strWhereStatus As String
    Dim strWhereChefInit As String
    Dim strWhereLandsdel As String
    Dim strDato As String
    Dim sDay As String
    Dim sMonth As String
    Dim sYear As String
    Dim bWhere As Boolean
   
    strWhereDato = ""
    strWhereStatus = ""
    strWhereChefInit = ""
    strWhereLandsdel = ""
    bWhere = False

    If Not IsNull(Me.txtDato) Then
        If Me.txtDato.Value <> "" Then
            sDay = Right("00" & Day(Me.txtDato), 2)
            sMonth = Right("00" & Month(Me.txtDato), 2)
            sYear = Year(Me.txtDato)
            'strDato = sDay & "/" & sMonth & "/" & sYear
            strDato = sMonth & "/" & sDay & "/" & sYear
            strWhereDato = "WHERE Dato = #" & strDato & "# "
            bWhere = True
        End If
    End If

    If Not IsNull(Me.Status) Then
        If Me.Status <> "" Then
            If bWhere Then
                strWhereStatus = "AND StatusID = " & Me.Status & " "
            Else
                strWhereStatus = "WHERE StatusID = " & Me.Status & " "
                bWhere = True
            End If
        End If
    End If

    If Not IsNull(Me.Chef) Then
        If Me.Chef <> "" Then
            If bWhere Then
                strWhereChefInit = "AND ChefInit = '" & Me.Chef & "' "
            Else
                strWhereChefInit = "WHERE ChefInit = '" & Me.Chef & "' "
                bWhere = True
            End If
        End If
    End If

    If Not IsNull(Me.landsdel) Then
        If Me.landsdel <> "" Then
            If bWhere Then
                strWhereLandsdel = "AND LandsdelID = " & Me.landsdel & " "
            Else
                strWhereLandsdel = "WHERE LandsdelID = " & Me.landsdel & " "
                bWhere = True
            End If
        End If
    End If
   
    If Me.txtDato = "" And Me.Status = "" And Me.Chef = "" And Me.landsdel = "" Then
        getWHEREclause = ""
        Exit Function
    End If
   
    getWHEREclause = strWhereDato & strWhereStatus & strWhereChefInit & strWhereLandsdel
End Function