Jeg vil mene, at det her eksempel ligner din situation, mest:
<%
option explicit ' Variabler (som vi skal bruge) SKAL dimmes! = undgå stavefejl
response.buffer = true ' hele siden dannes, inden den sendes til browseren
on error resume next ' den skal fortsætte med scriptet, selvom der opstår fejl
function TypenTal(input)
' Denne funktion tester om id'en (der hentes via request.querystring("id")) er af typen tal.
' Hvis der er bogstaver og/eller andre tegn, er der fejl, og det skal den melde.
for i = 1 to len(input)
if instr("1,2,3,4,5,6,7,8,9,0,", mid(input, i, 1) & ",") < 1 then
response.write "<br><br><b>Fejl! Varenummeret passer ikke!</b>"
input = ""
end if
next
TypenTal = CInt(input)
end function
'-- Dette er så vores test-array:
Dim myI, myA
ReDim myI(2), myA(2)
myI(0) = 211: myI(1) = 342: myI(2) = 754
myA(0) = 2: myA(1) = 5: myA(2) = 3
response.write "Følgende id'er kan bruges til testen (formatet er: indexnummeret kolon id x antal):<br><br>"
for i = 0 to ubound(myI)
response.write i & ": " & myI(i) & " x" & myA(i) & "<br>" & vbCrLf
next
response.write "<br><a href=""" & request.servervariables("script_name") & "?id="">Klik på dette link, og skriv id-nummeret i urlen</a>" & vbCrLf
' Variablerne vi skal bruge:
dim i
dim intIndex ' kommer til at indeholde indekset til elementet, i arrayen
dim Elementet ' kommer til at indeholde, elementet i arrayen
dim id ' kommer til at indeholder id'en fra urlen
dim fejl ' kommer til at indeholde fejlmeddelser, når der opstår fejl
fejl = "" ' nulstil fejlmeddelelse
'-- Dette er selve funktionene, der fjerner elementet fra arrayen:
sub Fjern(arrElement)
'-- Da jeg har indsæt myI og myA direkte i koden, er denne IF-sætning overflødig:
'if not IsArray(myI) then
' ' Den valgte array, er ikke en array.. vis en fejlmeddelelse:
' response.write "<br><b>Fejl! Den valgte array er ikke en array!</b><br><br>"
' exit sub
'end if
'-- Her findes indekset for det valgte elements (i variablen "Elementet")
' sæt intIndex (indekset) til - 1, hvilket er uden for arrayen. Det vil give fejl,
' hvis elementet ikke findes i arrayen (og kun hvis det ikke findes):
intIndex = - 1
for i = 0 to ubound(myI)
if myI(i) = Elementet then
' elementet er fundet, skriv indekset i variablen intIndex, og hop ud af loopen
intIndex = i
exit for
end if
next
if intIndex < LBound(myI) or intIndex > UBound(myI) then
' indekset er uden for arrayen = det findes ikke
response.write "<br><b>Fejl! Den valgte vare findes ikke i kurven!</b><br><br>"
exit sub
end if
for i = intIndex to UBound(myI) - 1
' ret arrayen til:
myI(i) = myI(i + 1)
myA(i) = myA(i + 1)
next
' id:
redim preserve myI(Ubound(myI) - LBound(myI) - 1) ' fjern det overflødige element
' antal:
redim preserve myA(Ubound(myA) - LBound(myA) - 1) ' fjern det overflødige element
end sub
id = TypenTal(request.querystring("id")) ' test værdien af id, fra request.querystring("id")
if id <> "" then
Elementet = id ' dette er elementet (id) i arrayen, der skal fjernes. I eksemplet: 342
' --- Kodeblok - før sletning (denne kodeblok kan fjernes) - Start
response.write "<br><br>Før sletning (formatet er: indexnummeret kolon id x antal):<br><br>"
for i = 0 to ubound(myI)
response.write i & ": " & myI(i) & " x" & myA(i) & "<br>"
next
response.write "<hr>"
' --- Kodeblok - før sletning (denne kodeblok kan fjernes) - Slut
' ***************************************************************************
Fjern Elementet ' Fjerner elementet fra arrayen (via funktionen "Fjern"):
'-- Du kan nu bruge myI og myA som array, til at gemme data i sessionerne
' Eksempel:
'
' Session("id") = myI
' Session("antal") = myA
' ***************************************************************************
' --- Kodeblok - efter sletning (denne kodeblok kan fjernes) - Start
response.write "<br><br>Efter sletning (formatet er: indexnummeret kolon id x antal):<br><br>"
for i = 0 to ubound(myI)
response.write i & ": " & myI(i) & " x" & myA(i) & "<br>"
next
response.write "<hr>"
' --- Kodeblok - før sletning (denne kodeblok kan fjernes) - Slut
end if ' denne END-IF tilhører id-testen.
'-- Her kan du vælge, om du vil vise brugeren en fejlmeddelelse, når der opstår fejl:
' Fejlkoden "0" betyder "ingen fejl". Vi checker lige om der er fejl:
if err.number <> 0 and id <> "" then
' Hvis der opstår fejl (fejlkoden er IKKE 0), skriv fejlnummer og fejlbeskrivelse:
response.write "<br><br>Der opstod en fejl:<br>" & err.number & " - " & err.description & "</b><br>"
end if
%>
/theSurfer
Ny bruger
Nybegynder
Opret
Preview
