Min excel-fil med vba-automatiseringer vokser til 10 gang størrelse

En mulighed kan være at slette alle tomme rækker og kolonner inden du gemmer. Har de været i brug optager de plads, også selv om deres indhold er slettet.

Jeg har haft samme problem med en fil på ca. 50 MB der steg til det dobbelte.
Jeg skulle rense en fil og manipulere en del data med VBA kodning og dette gjore at den steg i MB. Min løsning var at det færdige resultat via VBA blev kopieret over i et nyt ark som så blev gemt som kopien (ca. 36 MB). Jeg prøvede at REDIM men fik det ikke til at virke tilfredsstillende.

@Jan K:
Der opstår ikke nogle tomme rækker.

Og planen vedligeholder sig selv vha. VBA-automatiserineg der både tilføjer nye rækker, så planen altid rækker et helt år frem, og gamle rækker slettes også med VBA-automatiosering.

Ikke en egentlig løsning, men prøv evt at teste med 'show used range' og se hvad excel selv mener der er aktive områder i arkene.

@thomas_bk
Og hvor er det lige jeg kan finde  'show used range' ?

activesheet.usedrange.address
denne giver dig 'yderste' punkt.

brug evt.
msgbox activesheet.usedrange.address

eller denne

Sub Show_used_ranges()

Dim ws As Worksheet
Dim lCount As Long
Dim wsTemp As Worksheet
Dim rngF As Range
Dim lFields As Long
Dim strLC As String
Dim strSh As String
Dim sh As Shape

Application.EnableEvents = False
Application.ScreenUpdating = False
On Error Resume Next
 
  Set wsTemp = Worksheets _
      .Add(Before:=Sheets(1))
  lCount = 2
  lFields = 5
 
  With wsTemp
    .Range(.Cells(1, 1), _
      .Cells(1, lFields)).Value _
          = Array( _
              "Sheet Name", _
              "Used Range", _
              "Range Cells", _
              "Shapes", _
              "Last Cell")
  End With
 
  For Each ws In ActiveWorkbook.Worksheets
    If ws.Name <> wsTemp.Name Then
      strSh = ""
      strLC = ws.Cells _
        .SpecialCells(xlCellTypeLastCell) _
          .Address
      If ws.Shapes.Count > 0 Then
        For Each sh In ws.Shapes
          strSh = strSh & sh.TopLeftCell _
              .Address & ", "
        Next sh
        strSh = Left(strSh, Len(strSh) - 2)
      End If
 
      With wsTemp
        .Range(.Cells(lCount, 1), _
          .Cells(lCount, lFields)).Value _
          = Array( _
              ws.Name, _
              ws.UsedRange.Address, _
              ws.UsedRange.Cells.Count, _
              strSh, _
              strLC)
        'add hyperlink to sheet name
        .Hyperlinks.Add _
            Anchor:=.Cells(lCount, 1), _
            Address:="", _
            SubAddress:="'" & ws.Name _
                & "'!A1", _
            ScreenTip:=ws.Name, _
            TextToDisplay:=ws.Name
        'add hyperlink to last cell
        .Hyperlinks.Add _
            Anchor:=.Cells(lCount, lFields), _
            Address:="", _
            SubAddress:="'" & ws.Name _
                & "'!" & strLC, _
            ScreenTip:=strLC, _
            TextToDisplay:=strLC
       
        lCount = lCount + 1
      End With
    End If
  Next ws

With wsTemp
    .Range(.Cells(1, 1), .Cells(1, lFields)) _
      .EntireColumn.AutoFit
    .Rows(1).Font.Bold = True
End With

Application.EnableEvents = True
Application.ScreenUpdating = True

End Sub

@thomas_bk

Ja nu har jeg testet med dit forslag
div]msgbox activesheet.usedrange.address[/div]
og jeg fik udskrevet adresserne på området.
msgbox activesheet.usedrange.address
Jeg kan se at den yderste celle er den man kommer til hvis man bruger begge scroll-håndtag hhv. helt ud til højte og helt ned.

Kan jeg reducere dette område?

Marker alle tomme rækker og slet dem. Gentag med kolonner. Det er rækker og kolonner, du skal slette, ikke deres indhold. Gem så og se om ikke det har hjulpet.

@thomas_bk
Ja det var noget der hjalp:
Takker for dit fine input.

Resultatet blev så godt ar vi nu er tilbage på den oprindelige størrelse ca. 1,1 MB, og msgbox activesheet.usedrange.address udskriver netop adresen på det område jeg har aktive data i.

Takker for Jeres engagement og  hjælp.