script virker ikke i XP Wshshell.run

Øhh hvilken fejl får du???

//>Rune

jeg får ingen den kopier filen fint hvis ikke den eksitere eller skal opdateres men den åbner intet og ingen fejl

jeg er lidt pressede sidder hos en kunde og det virker fint på deres W2k men ikke XP

hvis jeg sætter en msgbox ind vises den også fint men den åbner ikke filen lige efter dne har givet mig msgbox



If s >= s1 Then
Set WshShell = CreateObject("WScript.Shell")
msgbox "ok"
WshShell.Run filespec
Set WshShell = Nothing

meget mystisk hvis jeg sætter msgboxen ind bagefter så køre det men det er jo ikke så smart


Set WshShell = CreateObject("WScript.Shell")
WshShell.Run filespec
msgbox"ok"
Set WshShell = Nothing
Else

En MsgBox() stopper scriptet, så det ikke afvikles...!
Så du må finde en anden løsning!

//>Rune

Men i realiteten så burde programmet jo blive kørt idet du klikker Ok på MsgBoxen!

//>RUne

jeg har jo ingen msgbox

Så prøv at fjern linjen:

Set WshShell = Nothing

//>Rune

ja men det sjove er at det virker hvis jeg sidder på 2000
men det virker også hvis jeg sætter en msgbox ind efter w.run

ja det har jeg prøvet det hjælper intet

Prøv lgie at fjern alle de steder hvor ud har skrevet
Set WshShell = Nothing

//>Rune

det hjalp intet

Hvad hvis du gør sådan her:

Set WshShell = CreateObject("WScript.Shell")
WshShell.Run filespec
msgbox"ok"
Set WshShell = Nothing
MsgBox("Får du denne popup frem?")
Else

//>Rune

så virker det hele perfekt programmet åbnes og begge popupperne virker

min eneste løsning er sætte ---WshShell.Popup " ", 1, "", 32--- ind efter hver wshshell.run


men hvis der er nogen der har en smarter løsning vil gerne høre

Ved ikke om det gør en forskel, men der er ingen grund til at oprette shell og fil-objekter flere gange - de kan snildt genbruges. Nedenstående virker fint på min XP:

Dim fso, f, f1
Dim strServerFile, strClientCopy

Set WshShell = CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
 
strServerFile = "\\server\Auktion\Databaser\frontend\hmfrontend.mdb"
strClientCopy = "c:\databaser\hmfrontend.mdb"

If fso.FileExists(strClientCopy) And fso.FileExists(strServerFile) Then
  Set f1 = fso.GetFile(strServerFile)
  Set f = fso.GetFile(strClientCopy)

  If CDate(f.DateLastModified) >= CDate(f1.DateLastModified) Then
      ' Klient up-to-date. Start databasen
      WshShell.Run strClientCopy
  Else
      ' Nyere fil på serveren. Opdatér og start databasen
      WshShell.Popup "Ny version af databasen" & vbCrLf & "vent venligst! ", 2, "Opdatering Af frontend", 32
      f1.Copy (strClientCopy)
      WshShell.Run strClientCopy
  End If
Else
  ' Tjek om der er forbindelse til serveren. Hvis ikke, start databasen lokalt hvis den findes
  If Not fso.FileExists(strServerFile) Then
      msgbox "Du er ikke tilknyttet serveren" & vbCrLf & "Opdatering af frontenden ikke muligt" & vbCrLf & "Såfremt du er til knyttet serveren kontakt JHC 20706424"
      If fso.FileExists(strClientCopy) Then
        WshShell.Run strClientCopy
      Else
        MsgBox "Ingen lokal database", 16
      End If
  Else
      ' Der er forbindelse til filen på serveren - start kopiering
      Set WshShell = CreateObject("WScript.Shell")
      WshShell.Popup "Der er ingen frontend medens kopieringen foretages" & vbCrLf & "vent venligst! ", 2, "Opdatering Af frontend", 32
      Set f1 = fso.GetFile(strServerFile)
      f1.Copy (strClientCopy)
      WshShell.Run strClientCopy
  End If
End If

' Ryd op
Set f = Nothing
Set f1 = Nothing
Set fso = Nothing
Set WshShell = Nothing