Hente ut info om Office

Tjaa, du kan hente den ud sådan her:

set word = CreateObject("Word.Application")
msgbox word.version
word.quit
set word=nothing

//>Rune

Hmm fandet det her:

Sub FindJetVersion()
Dim filesys, demofile, sVersion
Set filesys = CreateObject("Scripting.FileSystemObject")

On Error Resume Next

Set demofile = filesys.GetFile("C:\WINNT\SYSTEM32\MSJET40.DLL")

If Err.Number = 0 Then
    sVersion = filesys.GetFileVersion("C:\Winnt\System32\msjet40.dll")


      If Instr(1,sVersion,"4.0.7") > 1 Then
        Call Msgbox("Version 4 SP7 is available!")
      End If


Exit Sub
Else
Set demofile = filesys.GetFile("C:\WINNT\SYSTEM32\MSJET35.DLL")
  If Err.Number = 0 Then
    Call Msgbox("Version 3.5 is available!")
    Exit Sub
  Else
    Call Msgbox("Could not find any Jet versions!")
    Exit Sub
End If
End If


End Sub

Prøv med det hvis det andet ikke virker... (Det andet er utestet)

Ellers prøv med dette hvis det andet ikke virker:

Dim sPath
Dim filesys
Set filesys = CreateObject("Scripting.FileSystemObject")
sPath = filesys.GetSpecialFolder(1)
On Error Resume Next
Msgbox filesys.GetFileVersion(sPath & "\msjet40.dll")

//>Rune

Version af Office:

Here is a script that finds the newest Office version installed on a computer:

'HKLM\SOFTWARE\Microsoft\Office\10.0\Common\InstallRoot ' Office XP
'HKLM\SOFTWARE\Microsoft\Office\9.0\Common\InstallRoot ' Office 2000
'HKLM\SOFTWARE\Microsoft\Office\8.0\Common\InstallRoot ' Office 97

sRegPre = "HKLM\SOFTWARE\Microsoft\Office\"
sRegPost = "\Common\InstallRoot\"

Select Case True
  Case RegKeyExists(sRegPre & "10.0" & sRegPost)
    sOfficeVer = "XP"
  Case RegKeyExists(sRegPre & "9.0" & sRegPost)
    sOfficeVer = "2000"
  Case RegKeyExists(sRegPre & "8.0" & sRegPost)
    sOfficeVer = "97"
  Case Else
    sOfficeVer = "none"
End Select


WScript.Echo "Version of Office installed: " & sOfficeVer


Function RegKeyExists(sRegKey)
  Set oShell = CreateObject("WScript.Shell")
  RegKeyExists = True
  sRegKey = Trim (sRegKey)
  If Not Right(sRegKey, 1) = "\" Then
    sRegKey = sRegKey & "\"
  End if
  On Error Resume Next
  RegReadReturn = oShell.RegRead(sRegKey)
  If Err Then
    If LCase(Left(err.description,7)) = "invalid" Then
      'key not found...
      RegKeyExists = False
    End if
    Err.clear
  End if
  On Error Goto 0
End Function

Snowball