Slette linie i INI fil

' Dette system kan godt udbygges, så det kan kaldes med f.eks.:
' fjern.vbs "Userinterface=UK"
'
' hvor fjern.vbs er navnet på filen, og "Userinterface=UK" er den linie der skal fjernes.
'
' I mit eksempel hedder filen "data.ini", og er placeret i samme mappe som scriptet.
' data.ini indeholder:
' [Notes]
' Userinterface=UK
' Directory=C:\Lotus\Notes\Data
' KitType=1

Option Explicit ' ALLE variabler skal defineres/dimmes!
Dim fso, f, indhold, tmp ' definer/dim variabler

Set fso = CreateObject("Scripting.FileSystemObject") ' Opret Filsystem objektet

''''''''''''''''''''' Læs fra fil:
Set f = fso.OpenTextFile("data.ini",1) ' indstil fil til læsning

' Læs linie for linie indtil slutningen af filen
Do While not f.AtEndOfStream ' forstær indtil slutning af filen
  tmp = f.Readline ' put den nuværende linie i variablen "tmp"
 
  ' Hvis linien ikke er "Userinterface=UK", put den i variablen "indhold", plus linie skift
  if tmp <> "Userinterface=UK" then indhold = indhold & tmp & vbCrLF
Loop

msgbox indhold ' vis indholdet af variablen "indhold"
f.close


''''''''''''''''''''' Skriv til fil:
Set f = fso.CreateTextFile("data.ini", True) '

' Hvis du vil fjerne den tomme linie nederest i filen, fjern ' tegne:
' indhold = Left(indhold, len(indhold) - 2)

f.Write(indhold) ' indholdet af variablen "indhold" skrives til filen
f.Close ' objektet lukkes

set f = nothing
set fso = nothing

Rettelse:

' Dette system kan godt udbygges, så det kan kaldes med f.eks.:
' fjern.vbs "data.ini" "Userinterface=UK"
'
' hvor:
' - fjern.vbs er navnet på kode-filen
' - data.ini er navnet på data filen
' - "Userinterface=UK" er den linie der skal fjernes fra data filen.

Da det er testet, og virker, smider jeg et svar.
Hvis du ikke kan bruge det, skriv venligst hvorfor.

Det virker perfekt, tak for hjælpen.

thesurfer må lige skrive igen, jeg kom til at afvise i stedet for at acceptere, sorry.

Den er god nok :)
Jeg har fået points, og du har dermed (automatisk) afvist dit eget svar, hvilket du skulle :)