Slette flere linier i notes.ini

kan du ikke  lige smide det du har. Der er jo ingen grund til at starte forfra hvis der findes noget alleredd

Hermed det script jeg modtog, og som kan slette en linie:

' Dette system kan godt udbygges, så det kan kaldes med f.eks.:
' fjern.vbs "Userinterface=UK"
'
' hvor fjern.vbs er navnet på filen, og "Userinterface=UK" er den linie der skal fjernes.
'
' I mit eksempel hedder filen "data.ini", og er placeret i samme mappe som scriptet.
' data.ini indeholder:
' [Notes]
' Userinterface=UK
' Directory=C:\Lotus\Notes\Data
' KitType=1

Option Explicit ' ALLE variabler skal defineres/dimmes!
Dim fso, f, indhold, tmp ' definer/dim variabler

Set fso = CreateObject("Scripting.FileSystemObject") ' Opret Filsystem objektet

''''''''''''''''''''' Læs fra fil:
Set f = fso.OpenTextFile("data.ini",1) ' indstil fil til læsning

' Læs linie for linie indtil slutningen af filen
Do While not f.AtEndOfStream ' forstær indtil slutning af filen
  tmp = f.Readline ' put den nuværende linie i variablen "tmp"
 
  ' Hvis linien ikke er "Userinterface=UK", put den i variablen "indhold", plus linie skift
  if tmp <> "Userinterface=UK" then indhold = indhold & tmp & vbCrLF
Loop

msgbox indhold ' vis indholdet af variablen "indhold"
f.close


''''''''''''''''''''' Skriv til fil:
Set f = fso.CreateTextFile("data.ini", True) '

' Hvis du vil fjerne den tomme linie nederest i filen, fjern ' tegne:
' indhold = Left(indhold, len(indhold) - 2)

f.Write(indhold) ' indholdet af variablen "indhold" skrives til filen
f.Close ' objektet lukkes

set f = nothing
set fso = nothing

det nemmeste er at ændre linien
if tmp <> "Userinterface=UK" then indhold = indhold & tmp & vbCrLF

til
if (tmp <> "det der skal slettes") OR (tmp <> "det der også skal slettes") then indhold = indhold & tmp & vbCrLF

Ovenstående kan udvides til mange linier
if (tmp <> "...") OR (tmp <> "...") OR (tmp <> "...") then ....

Jeg har nu testet flere gange, og må desværre konstatere at den ikke sletter linierne. Der kommer ingen fejl, der sker blot intet.

min fejl. der skal stå AND imellem istedet. Du kan med fordel bruge trim foran tmp, sletter den også linien hvis der måtte være et mellemrum efter, så prøv at skrive

if (Trim(tmp) <> "EXTMGR_ADDINS=NCExtMgrClient") AND (Trim(tmp) <> "AddInMenus=NCMenu") then indhold = indhold & tmp & vbCrLF

Yes det virker, Tak for hjælpen.

Øhh! fik du dine point??

ja, og tak

Hej Tofte

Et lille tillægsspørgsmål, kan man lave det så den kun retter hvis filen notes.ini findes? jeg oplever at scriptet fryser hvis filen ikke findes.

Jo, du kan tilføje
if fso.fileexists("data.ini") then
ovenover
Set f = fso.OpenTextFile("data.ini",1) ' indstil fil til læsning


og end if oven over
set fso = nothing i bunden