Søge efter flere værdier i en ini fil??

åh ja... lige en tilføjelse. Fejlhåndtering er ikke min stærke side i VBScript. Hvis value ikke findes skal den blot "hoppe" videre i scriptet.

sINIFileName = "test.ini"

sSearchString = InputBox("Enter name to search for")
If sSearchString = "" Then
  WScript.Quit(1)
End If

Set fso = Wscript.CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextfile(sINIFileName, 1)

sRes = ""

Do
  sCurLine = f.ReadLine
  If InStr(sCurLine, "Name = """ & sSearchString & """") > 0 Then
      sCurLine = f.ReadLine
      aValue = Split(sCurLine, "=")
      sRes = Trim(Replace(aValue(1), """", ""))
      Exit Do
  End If
Loop Until f.AtEndOfStream

f.Close
Set f = Nothing
Set fso = Nothing

If sRes <> "" Then
  MsgBox "Value of '" & sSearchString & "': " & sRes
Else
  MsgBox "'" & sSearchString & "' not found!"
End If

Erstat "test.ini" med din INI-fil ;-)

Ups, glemte lige at tjekke om Value eksisterer... Det kommer om lidt...

Sådan:

sINIFileName = "test.ini"

sSearchString = InputBox("Enter name to search for")
If sSearchString = "" Then
  WScript.Quit(1)
End If

Set fso = Wscript.CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextfile(sINIFileName, 1)

sRes = ""

Do
  sCurLine = f.ReadLine
  If InStr(sCurLine, "Name = """ & sSearchString & """") > 0 Then
      sCurLine = f.ReadLine
      If InStr(sCurLine, "Value") = 1 Then
        aValue = Split(sCurLine, "=")
        sRes = Trim(Replace(aValue(1), """", ""))
        Exit Do
      End If
  End If
Loop Until f.AtEndOfStream

f.Close
Set f = Nothing
Set fso = Nothing

If sRes <> "" Then
  MsgBox "Value of '" & sSearchString & "': " & sRes
Else
  MsgBox "No value for '" & sSearchString & "'!"
End If

Mon ikke du kan bruge dette:

Option Explicit
dim Filsystem, stream,tekst, navn, fundet
Set FilSystem=CreateObject("Scripting.FileSystemObject")
Set stream=filsystem.openTextFile("Testfil.txt")
navn=InputBox("Indlæs navn: ")
while not stream.AtEndOfStream
  tekst=stream.readline()
  If Instr(tekst,"""" & navn & """")>0 then
    tekst=stream.readline
    MsgBox tekst
    fundet=true
  end if
wend
if not fundet then
  MsgBox "Navnet findes ikke"
end if
stream.close
set stream=nothing

nmh>> Mange tak - det var lige det jeg skulle bruge. Der skal ske lidt mere med det fundne, men det vil jeg kaste mig over...

Adam>> Jeg kunne desværre ikke få din løsning til at finde noget. Jeg har prøvet på alle måder, men den kan ikke finde værdierne. Virker det hos dig?

Ja, det virker fint. Den er dog case-sensitiv, så hvis du søger efter ABC finder den ikke value for abc, etc.

Vær opmærksom på at nmh's svar ikke tager højde for hvis der ikke findes en value-line efter name-linien, så hvis din INI-fil fx ser således ud:

Section begin
Name = "ABC"
Section end

Section begin
Name = "ABCD"
Value = "123.ABC"
Section end

Vil nmh's script returnere "Section end"...

Det har du ret i... men jeg kan stadig få dit svar til at virke... og jeg ER opmærksom på case-sensitive... :-(

Jeg har endda prøvet at kopiere en linie fra ini filen til inputboxen uden held...

Du skal kun skrive det efter =-tegnet og uden "

fx: ABC

ok... fejlen er fundet.

Det er flg. det er galt med.

If InStr(sCurLine, "Value") = 1 Then

Hvis den laver det check så finder den ikke noget. Men hvis jeg fjerner linien, virker det...?

Skal linien ikke hedde:

If InStr(sCurLine, "Value") > 0 Then

Så virker det i hvert fald... :-)

Takker for point. :o)
Hvad skal der ske med det fundne?
Jeg valgte jo blot at udskrive hele linien value="...

nmh>> Ja, det er klart. Jeg bad jo også bare om værdien. Den skal såmænd bare renses og bruges senere i scriptet. Men det er klaret. Jeg har dog vlagt at bruge adams løsning i stedet, så han skulle egentlig have haft dine point :-) Men det finder jeg selv ud af med ham. Tak for din hurtige hjælp i dag. Jeg håber jeg kan trække lidt på dig en anden god gang.

Du er velkommen.

InStr(sCurLine, "Value") = 1 tjekker om næste linie (efter Name = "...) er en tilhørende Value-line (dvs. om linien _starter_ med 'Value'). Det kræver dog at Name, Value parret står præcis som du skrev i dit spm. Gør de det i din INI-fil? (dvs. uden foranstående mellemrum og med stort V)

InStr(sCurLine, "Value") > 0 vil virke i de fleste tilfælde, men fejle hvis en section fejlagtigt er defineret fx med en kommentar således:

Section begin
Name = "ABC"
'remember to write the Value on this line...
Section end

Hvis du kan stole på at INI-filen ikke har sådanne sections kan du godt nøjes med InStr .... > 0

Ellers prøv dette i stedet:
If InStr(Trim(LCase(sCurLine), "value")) = 1 Then