Næste ledige drevbogstav

Hvis du mapper vha. kommandoen "NET USE" kan du bruge * i stedet for drevbogstav. Den mapper til næste ledige enhedsnavn.
Klippet ud fra "NET HELP USE":

NET USE tilslutter en arbejdsstation til en delt ressource eller frakobler
en arbejdsstation fra en delt ressource. Når kommandoen bruges uden parametre,
vises arbejdsstationens tilslutninger.

enhedsnavn:      Tildeler et navn for at tilslutte sig ressourcen eller
                angiver den enhed, der skal frakobles. Der findes to typer
                enhedsnavne: diskdrev (D: til og med Z:) og printere
                (LPT1: til og med LPT3:). Brug *-tegnet for at tildele
                det næste ledige enhedsnavn.

Jeg bruger desværre ikke Net Use...
Mit script ser sådan ud:

Set Network = Wscript.CreateObject("Wscript.Network")
Set FSO = CreateObject("Scripting.FileSystemObject")
Set Shell = Wscript.CreateObject("Wscript.Shell")

strCompName = Network.ComputerName
strUserName = Network.UserName
strVelk = "Velkommen"
StrTitel = "Login Script"
StrServer = "Server"
StrShare = "E\Users\tbm"

If FSO.DriveExists("Z:") = False Then
    Network.MapNetworkDrive "Z:", ("\\" & StrServer &"\" & StrShare)
    Shell.Popup "PC navn: " & strCompName &vbCRLF &_
                "Bruger: " & strUserName &vbCRLF &_
                "Drev Z er tilsluttet \\" & StrServer &"\" & StrShare             
Else
    'Shell.Popup    "Drev Z kunne ikke tilsluttes...",10,StrTitel,48
End If

Der er også den mulighed at løbe alle bogstaverne fra D til Z igennem med en løkke, der tjekker på FSO.DriveExists:

strDrive = "D"
Do While (FSO.DriveExists(strDrive & ":")) And (strDrive < "Z")
  strDrive = Chr(Asc(strDrive) + 1)
Loop
If (FSO.DriveExists(strDrive & ":")) And (strDrive = "Z") Then
  ' Ingen ledige drevbogstaver - fejlhåndtering skal ind her
Else
  Network.MapNetworkDrive strDrive & ":", ("\\" & StrServer &"\" & StrShare)
    Shell.Popup "PC navn: " & strCompName &vbCRLF &_
                "Bruger: " & strUserName &vbCRLF &_
                "Drev " & strDrive & " er tilsluttet \\" & StrServer &"\" & StrShare
End If

Jammen det er jo nydeligt, tak for din hjælp!

velbekomme :)  så skal jeg bare lige have kradset pointene hjem c",)

Smart ..
Men måske er der ikke en så god ide at gøre det tilfældigt hvilket bogstav den bruger. Mange programmer er afhændige af bruger drev og sådan.

Det er også en god ide, hvis det er det samme hele vejen rundt. Bare et ide.

Vil det script der foresten ikke mappet et nyt bogstav op hvergang? Altså hvis den allerede er mappet til f.eks. E:, vil den så ikke næste gang mappe til F:

Jeg går ud fra det skal bruges som logon-script eller lignende, og derfor vil bogstavet E: jo altid være ledigt før scriptet bliver kaldt - med mindre det i mellemtiden er blevet permanent mappet.

Ja det er rigtigt, men nogle gange vil Windows 2000 og XP ikke slippe drevmappings, eller hvis en bruger giver sig til at gøre noget indhold på drevet tilgængeligt offline.

Det er eller smart med den Ascii værdi, den kendte jeg ikke..