Læse registry værdi , man ikke kender navnet på

Dette script gemmer alle undernøgler og værdier i en fil. Det kan selvf. lavs om, så den gemmer dem i et array, men ideen burde være der:
const HKEY_LOCAL_MACHINE = &H80000002
const REG_SZ = 1
const REG_EXPAND_SZ = 2
const REG_BINARY = 3
const REG_DWORD = 4
const REG_MULTI_SZ = 7
Const ForAppending = 8
strComputer = "."

sub wr(msg)
    objTextFile.WriteLine(msg)
end sub

sub writeReg(strKeyPath)
    lcr= oReg.EnumKey(HKEY_LOCAL_MACHINE, strKeyPath, arrSubKeys)
    If lsc = 0 And IsArray(arrSubKeys) Then
    For Each subkey In arrSubKeys
        wr strKeyPath&"\"&subkey
        writeReg(strKeyPath&"\"&subkey)
    Next
    end if
    oReg.EnumValues HKEY_LOCAL_MACHINE, strKeyPath,arrValueNames, arrValueTypes
    IF IsArray(arrValueNames) then
        For i=0 To UBound(arrValueNames)
            Select Case arrValueTypes(i)
                    Case REG_SZ
                  vtype= "String"
                    Case REG_EXPAND_SZ
                        vtype="Expanded String"
                    Case REG_BINARY   
                        vtype="Binary"
                    Case REG_DWORD
                        vtype="DWORD"
                    Case REG_MULTI_SZ
                        vtype="Multi String"
            End Select
            wr strKeyPath&"\"&arrValueNames(i)&": Type="&vtype
        Next
    end if
end sub


Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("c:\reg.txt", ForAppending, True)

Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
strComputer & "\root\default:StdRegProv")

strKeyPath = "SYSTEM\CurrentControlSet\Control\Lsa"

writeReg(strKeyPath)
'wrr()
objTextFile.Close

du skal bare ænder strKeyPath = "SYSTEM\CurrentControlSet\Control\Lsa" til den nøgle du ønsker at se på.

Hej Tofte, jeg har ikke haft tid at afprøve dit svar , men det set fornuftigt ud.
mvj AJVM

Det virker ganske udemærket