Tid, minutter og "hvis"

Hvis du har plalagt mødetid i A og sluttid i B, og faktisk mødetid i C og faktisk sluttid i D, kan du bruge denne formel:

=HVIS(OG(IKKE(ER.TOM(C1));IKKE(ER.TOM(D1)));D1-C1;B1-A1)

Shit :o) Jeg kan sige at mit første tal altså min faktisk mødetid står i B6 til C6 og min Faktiske mødetid står i D6 til E6

og selve formlen i G 6

Hov noget vigtigt, Der står ALTID noget i den skemalagte tid men i den faktisk arbejdstid er udfyldt er det den der skal regnes med.. Altså der står altid
  B6      C6      D6    E6                     
  09:00    17:00              <<når ingen  anden tid         
  09:00    17:00  10:00  16:00 << når anden tid

=HVIS(OG(IKKE(ER.TOM(D6));IKKE(ER.TOM(E6)));E6-D6;C6-B6)

Formlen undersøgerom der står noget i faktisk tid. Gør der det, trækker den de to tider fra hinanden. Ellers trækker den tiderne i skemalagt tid fra hinanden i stedet.

Jubii det virker du er en skat... Så har jeg sådan set et sprøgesmål mere Hvis vi arbejder fra 14:00 - 22:30
Så ligger en del af timerne efter 17:00 og så skal vi have tilæg for de timer der ligger fra 17:00 - 22:30
kan det lade sig gøre at få den til at regne det ud, det vil sige at mit tillæg skal stå i kolonne I 6
Kan jeg det?

Ja - alt kan lade sig gøre :-) Jeg vender lige tilbage.

Jeg går ud fra, at det kun er faktisk tid" der kan give overarbejde.

I I6 indsætter du : =HVIS(E6>17/24;E6-17/24;0), hvor E6 fortsat er faktisk gå-hjem tid. Det giver så det antal timer, du skal have tillæg for, fx 5:3+ i dit eksempel. Skal den også regne tillægget ud i kr og ører, kan du gøre det med denne formel:

=I6*24*tillægget pr time i kr.

Nej det er ikke kun den faktiske tid der kan give tid efter 17:00 det kan den den aktuelle tid også, på samme måde
Jeg kan godt være skemalagt med 09:00 - 22:30
men arbejde 12:00 - 22.30

Nu kan jeg ikke få den til at udregne summen af alle timerne det giver ialt, lige som man plejer at gøre.. Hvordan kan det være

Godt så!

Prøv med denne i stedet

=HVIS(ER.TOM(E6);HVIS(C6>17/24;C6-17/24;0);HVIS(E6>17/24;E6-17/24))

Hvad sker der, når du prøver at udregne summen af alle timerne.

Hvordan kan det være den ikke vil regne summen ud af alle mine totale timer..

=SUM(G6:G36) den skriver 00:00 som resultat

Har du mulighed for at prøve at sende arket til mig? kronsell snabela adslhome.dk

ja det kan du tro
den er på vej, finder lidt strøm til den bærbare først

Jeg venter :-)

Den er nu sendt afsted... Håber du kan se hvad det er jeg mener

Ret formatet for sammentællingscellen til brugerdefineret format [tt]:mm

Hmm det hjælper ikke, den skriver stadig 00:00

jeg fandt en der hed [t]:mm:ss men der er ingen der giver lov til kun [tt]:mm hvilket der vil være optimal da vi ikke bruger sekunder

nu virker det næsten det med efter 17. jeg havde bare ikke tænkt over at jeg også godt kan ske og møde klokken 18:00 - 22:30 så dur den ikke :(

=HVIS(ER.TOM(E6);HVIS(C6>17/24;C6-17/24;0);HVIS(E6>17/24;E6-17/24))  < den står til 24 den retter jeg til 06 da det hedder 17 - 06 tillæg.. Men den vil ikke regne fra klokken 18, kan man evt noget med 17 eller større end?

For sammentælling skal du ikke lede efter nogen formater. Bare vælg brugerdefineret og så skriv det, jeg viste i ruden øverst. så kan du undgå sekunderne.

Det andet ser jeg lige på.

Du skal ikke rette i 24 til 6 formlen. De 24 har intetet med kl. 24 at gøre.

ok har fundet ud af det og prøvede.. jeg kan se at jeg som det er nu heller ikke kan komme på arbejde til klokken 13:00-01:00 eks.

og formlen med tillæg tager ikke forbehold for min aktuelle tid men kun min faktiske tid :s
Er lige ved at tro jeg er kommet ud i noget hvor jeg slet ikke kan bunde.. jeg er meget glad for at du hjælper mig, da det er et kæmpe ønske at jeg ikke selv skla regne ud men at den gør det for mig..
kram til dig

Du har helt ret. Problemet er, at min formel løste det problem, du skitserede i første omgang. Nu viser det sig så, at der alngt flere situationer, som formeln skal tage højde for, og det betyder, at den skal være uligt meget mere kompleks. Lad os derfor få de rigtige facts på bordet.

hmm jeg ved ikke rigtig hvad jeg skal fortælle mere

Du er nødt til at fortælle mig

1) Hvordan kan skemalagt tid teoretisk ligge (begyndelse/slutning)
2) Hvornår kan faktisk tid ligge (begyndelse slutning).
3) Skal faktisk tid ALTID gælde frem for skemalagt tid?
4) Kan skemalagt eller faktisk tid ligge på  begge sider af midnat?

5) Hvad sker der, hvis du fx arbejder fra 01:00 til 06:00. Udløser det så også tillæg?
6) Eller hvis du arbejder fra 06:00 til 19:00 skal der så gives tillæg for timerne både før 6 og efter 17?

jeg havde ikke tænkt så langt at det faktisk bliver rigtig svært det her, men det er ikke nødvendigt at de tillæg kommer på, dem kan jeg bare droppe og skrive i hånden..
Det er fordi jeg er pædagog og kan af og til arbejde fra 20:00-01:00 også så det er så indviklet for mig at fortælle.. når jeg skal skrive det undskyld

Jeg kan prøve.. håber jeg kan gøre det og hvis du vil hjælpe er jeg selvfølgelig meget glad, men du må gerne sige fra hvis det er for tosset

Hvis du prøver at beskrve tidsreglerne, så skal jeg prøve at lave regnearket :-9

1) skemalagt tid kan ligge fra 00:00 til 00:00 det vil sige hele døgnet rundt
2) og det samme gælder den faktiske tid 00:00- 00:00
3) ja faktisk tid skal altid gælde frem for skemalagt tid da det er den tid jeg arbejder´, hvis der evt er kommet noget op møder, sygdom osv.
4)ja skemalagt tid kan ligge på begge sider af midnat.. men gør det yderst sjælden typisk fra morgen til eftermiddag.'
5) ja vores tillæg gælder fra 17 eftermiddag til 06 morgen det vil sige jeg kan godt ske og skal møde klokken 18 så det kan ikke altid regnes ud fra 17
6) ja hvis jeg arbejder fra 05:00-19:00 skal jeg have både tillæg for timen før 6 og timerne efter 17..

tak du er sød:o)

OK. Jeg ser på det, men det kan godt tage et stykke tid før jeg venderv tilbage. Jeg er nødt til også at passe mit arbejde ind imellem :-(

Åh ja det er jo det man er nød til.. Jeg er sådan set også på arbejde, men prøver og kigge ind om en time.. Hvad arbejder du som?

Jeg underviser i IT mm. :-), blandt andet Excel

hehe Kan jeg ikke komme på kursus så, det er træls når man ikke selv kan... l

Kan du ikke sætte en kursist til at lave det :p

Desværre er der ikke lige nogen kursister ved hånden. Denne uge står på administrativt arbejde.

åhh ok.. hvis jeg skal forklare det bedre end jeg har gjort, så sender jeg dig mit nummer så kan du ringe.. Hvor i landet underviser du

Helt i orden. Jeg underviser i Lyngby.

Ok.. Jeg vil lige gå op og være lidt sammen med nogle søde børn, men jeg kigger ned om ikke så længe.. Hvis du skal bruge nr. så bliver det pr. mail.. stadig 1000 Tak for hjælpen

Nå jeg var gået fra computeren, der var en der havde taget min USB ud uden og lukke mine ting ned, så nu er det forsvundet, nu er jeg da lidt træt af det..

Jeg ser på det i aften, og vender tilbage i morgen.

Sødt af dig :o) tak

Det tog lidt længere tid, end jeg regnede med, og der er stadig en enkelte skavank, som jeg ikke har fået løst, men here goes:

I G-kolonnen skal du beregne det antal timer, der er arbejdet. Det gør du med denne formel:

=HVIS(OG(IKKE(ER.TOM(D6));IKKE(ER.TOM(E6)));(E6<D6)+E6-D6;(C6<B6)+C6-B6)

I H-kolonnen skal du så beregne hvor timer, der liggen mellem 17 og 6. Det kan du gøre med denne formel:

=G6-HVIS(ELLER(ER.TOM(D6);ER.TOM(E6));ABS(MAKS(MIN(C6+(C6<B6);17/24);6/24)-MIN(MAKS(B6;6/24);17/24));ABS(MAKS(MIN(E6+(E6<d);17/24);6/24)-MIN(MAKS(D6;6/24);17/24)))

Problemet, hvor den regner forkert, opstår hvis en vagt starter efter 17 en dag, og slutter efter 6 næste dag. Så tager den alle timerne med. altså en vagt fra 18:00 til 10:00 vil give 16 17-6 timer, ikke de 12 den skulle give.

Ja jeg kan se du har været på arbejdeDet er rigtig flot og dejligt at du vil hjælpe mig, men det sidste problem er relativt lille da det er en sjældenhed at man arbejder med de timetal..
Det man kan se når man sætter den sidste formel ind i kolonne H, er at den ikke tager forbehold for det faktiske timetal men kun det der står i skemalagt tid.. Hvis man sætter noget ind i faktisk tid så melder den formel fejl.. Men den er så lang at jeg har utrolig svært ved at gennemskue det..

Så tror jeg den er ved at være der. Jeg sender dit regneark tilbage med formlerne indsat, men for god ordens skyld kommer løsningen også her:

I kolonne G (Timer I alt) skal du have denne formel:
=HVIS(ER.TOM(B6)=SAND;"";HVIS(ELLER(IKKE(ER.TOM(D6));IKKE(ER.TOM(E6)));(E6<D6)+E6-D6;(C6<B6)+C6-B6))

Den kan gøres nemmere fordi =Sand kan fjernes fra begyndelsen af formlen, men jeg har ladet den stå for forståelsens skyld. Formlen beregner det samlede antal timer og minutter, uanset om du arbejder "over midnat". Er hverken "Skemalagt tid" eller "Præsteret tid" udfyldt, vises cellen tom. Ellers bruger den "Præsteret tid", hvis den er udfyldt og i modsat fald anvendes "Skemalagt tid".

Så kommer den svære, den der beregner tillægstiden. Den kræver lidt forberedelse. Jeg har oprettet to hjælpeceller. Den ene indeholder tidspunktet, hvor tillægget begynder (lige nu kl. 17.00). Den anden indeholder så det tidspunkt, hvor tillægget begynder, lige nu kl. 06:00. Disse to celler har jeg navngivet. De hedder hhv. BT og ST. Hvis man senere ændrer reglerne, så I får tillæg fx fra kl. 19:00 til kl. 03:00, skal du bare tidspunkterne i de to celler, så skulle formlen gerne regne rigtigt med de nye tider. Formlen, der bregner tillægget ( i H6), ser nu sådan således ud:

=HVIS(ER.TAL(HVIS(ELLER(ER.TOM(D6);ER.TOM(E6))=SAND;"";(E6<=D6)*(1-BT+ST)+MIN(ST;E6)-MIN(ST;D6)+MAKS(BT;E6)-MAKS(BT;D6)));HVIS(ELLER(ER.TOM(D6);ER.TOM(E6))=SAND;"";(E6<=D6)*(1-BT+ST)+MIN(ST;E6)-MIN(ST;D6)+MAKS(BT;E6)-MAKS(BT;D6));HVIS(ELLER(ER.TOM(B6);ER.TOM(C6))=SAND;"";(C6<=B6)*(1-BT+ST)+MIN(ST;C6)-MIN(ST;B6)+MAKS(BT;C6)-MAKS(BT;B6)))

Igen kan man ændre på formlen ved at fjerne noget =SAND, men hvis du vil det, kan du s'gu selv gøre det ;-)

Formlen undersøger om "Præsteret tid" er udfyldt. I givet fald bruger den disse tal i beregningerne, ellers bruger den "Skemalagt tid". Er ingen af delene udfyldt vises resultatet som en tom celle. Formeln virker både ved arbejde hen over midnat, og hvis du skal have tillæg både før 6 og efter 17 på samme vagt. Derimod kan den ikke bruges, hvis en vagt varer mere end 24 timer. Har du fx vagt kl. 14.00 til 15.00 næste dag, bliver det kun regnet som 1 time. Skal den kunne det sidste også, kræver det at du skal indtaste såvel dato som tidspunkt (Og det gider jeg ikke tage højde for lige nu).

I I-kolonnen omregnes tallet fra H-kolonne så til decimaler, så kan gange det med tillægsbetalingen og regne dit samlede tillæg ud. Formeln i I6:

=HVIS(H6=0;"";HVIS(IKKE(ER.TAL(H6));"";H6*24))

Hvis H6 er tom eller indeholder 00:00 timer, vises celler i I-kolonnen tomme.

I "I alt cellerne" nederst har jeg erstattet dine additionsformler, med SUM formler, der er meget mere effektive i denne sammenhæng.

G38 og H38 er formateret med brugerdefineret format [t]:mm for at kunne viser timer over 24.

Og tak til Harald, Harlan og Sandy på microsoft.public.excel for inspiration :-)

1000 Tak for hjælpen Jkrons.. Man må godt nok sige det blev til en del mere end jeg havde regnet med i starten, men er dog utrolig taknemmelig for at du ville hjælpe så meget som du har gjort.. Du har fået absolut topkarakter og dine meget velfortjente point..
Det rigtige sjove er så at kunne forstå hvad det hele betyder, men det kræver nok lidt kursus.. Ved du om der er et sted på nettet hvor man kan se hvad tingene betyder - Det skal være et sted de snakker dansk?

Velbekomme. Jeg kender ikke umiddelbart et sted på nettet, og at give en præcis forklaring på formlens enkelte dele her, vil nokg føre for vidt.

Tak for point.